FilmAffinity (ES): New version of the script

[corydora]

Muchas gracias
Saludos

[AARON8888]

Gracias por la actualización del script, juliojs
Gran labor.

[Huginn]

Muchas gracias por el nuevo script.
¿Alguien sabe como modificarlo para que me descargue la versión pequeña de la carátula?

Gracias por adelantado ;-)

---------------------

Thanks a lot for the new script.
How can i modify the script to download the small cover?

Thanks in advance

[juliojs]

Muchas gracias por el nuevo script.
¿Alguien sabe como modificarlo para que me descargue la versión pequeña de la carátula?

Gracias por adelantado ;-)

---------------------

Thanks a lot for the new script.
How can i modify the script to download the small cover?

Thanks in advance

Añade ésta línea a la búsqueda de la carátula:

Code: Select all

Item := StringReplace(Item, 'large', 'main');

Si buscas "Picture" en el script lo encontrarás, esa parte tendría que quedar tal que así:

Code: Select all

// Picture
   LineNr := FindLine('http://pics.filmaffinity.com/', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr);
      Item := TextBetween(Line, '<a class="lightbox" href="', '" title="');
      if Length(Item) = 0 then
         Item := TextBetween(Line, '" src="', '"></a>');
         Item := StringReplace(Item, 'large', 'main');
      GetPicture(Item);
   end;

Espero que te sirva.

Saludos!

[Huginn]

Muchas gracias por el nuevo script.
¿Alguien sabe como modificarlo para que me descargue la versión pequeña de la carátula?

Gracias por adelantado ;-)

---------------------

Thanks a lot for the new script.
How can i modify the script to download the small cover?

Thanks in advance

Añade ésta línea a la búsqueda de la carátula:

Code: Select all

Item := StringReplace(Item, 'large', 'main');

Si buscas "Picture" en el script lo encontrarás, esa parte tendría que quedar tal que así:

Code: Select all

// Picture
   LineNr := FindLine('http://pics.filmaffinity.com/', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr);
      Item := TextBetween(Line, '<a class="lightbox" href="', '" title="');
      if Length(Item) = 0 then
         Item := TextBetween(Line, '" src="', '"></a>');
         Item := StringReplace(Item, 'large', 'main');
      GetPicture(Item);
   end;

Espero que te sirva.

Saludos!

¡Va perfecto!
¡Muchísimas gracias!

Saludos.

[AUPAKEPA]

Soy nuevo en Ant Movie Catalog y la verdad la estoy gozando .
Ademas os agradezco todo lo que me habéis ayudado en la integración.

Sin embargo vengo a ver si me podéis decir algo sobre esto:

En películas con titulo muy común solo aparecen los primeros títulos y la opción buscar mas esta des-habilitada.

Resultado que películas como X-men (2000) no la encuentro y esto se repite con mas facilidad con películas mas antiguas

Si me dijerais si estoy haciendo algo mal os lo agradeceria

[AARON8888]

Buenas tardes AUPAKEPA

Creo que tu pregunta es igual a la que yo formulé hace tiempo, y que aún espero respuesta de nuestro colega juliojs, ya que se lo mandé por mensaje privado.

Este era mi mensaje a juliojs:

+++ cito

Tengo una consulta a ver si me puedes ayudar.

Hay pocas veces que no puedo encontrar una película usando el script de FilmAffinity. Me explico. Voy a ponerte un ejemplo para que sepas claramente lo que te digo. Sigues mis pasos por si acaso te pierdes.

1º) Vamos a buscar información de internet con el script de FilmAffinity.

2º) La película a encontrar es "Ataque!" - (AKA "Ataque", "Ataquen"), el título original es "Attack!", de 1.956. La URL de FilmAffinity es http://www.filmaffinity.com/es/film280623.html

3º) Cuando le das a buscar por nombre traducido "Ataque!", o por título original "Attack!", la búsqueda del script te muestra un montón de títulos pero en ninguna de las búsquedas te llega hasta la película de 1.956, ya que hay muchos títulos en común. La última película que te aparece coincide con la última que aparecería en la primera página de búsqueda de la web FilmAffinity.
En el caso de búsqueda de "Ataque!" la última película que te aparece es de 1.964, y con "Attack!" hasta 1.978.

Realmente no sé si es un fallo del script o del programa AMC.
Al realizar la búsqueda con el script, la ventana tiene deshabilitado la casilla "Buscar más", esta sería una buena opción para seguir buscando, ¿no crees?

¿Hay alguna manera de importar el script poniendo el URL de la película de la web? Sería más directo.

Te dejo un ejemplo gráfico de la búsqueda por título original "Attack!".
Bájate el archivo pdf aquí para verlo.
https://mega.co.nz/#!WFghBTrQ!dC8Czxhbo ... PELtm8[url]

Gracias de antemano. A ver qué me puedes decir.

Cierro cita +++

[AUPAKEPA]

Exactamente eso. Si pudiéramos ponerlas a mano por Url seria fantástico o sin mas la opción buscar mas activa.

Es que por multitud de razones solo quiero funcionar con Film Affinity

de 2000 pelis me ha pasado con 30 no es mucho pero molesta

imagínate buscar títulos tan sencillos como Familia, tierra, Go......

[AUPAKEPA]

otra opcion seria poder añadir al campo de busqueda , año o director

[jacqlittle]

La solución en esos casos, que no es lo normal sino la excepción, es localizar en la web de Filmaffinity la película que se trate, ejecutar el script, y cuando te pide el título de la película copiamos la URL de Filmaffinity, le damos a "Aceptar" y ya se importa directamente esa película.

Imagino que el script como funciona es usando la búsqueda de la web y localizando la película en los resultados, pero claro, como hay ocasiones en las que son más de una página, modificar el script para tener contempladas tantas cosas ya creo que debe ser bastante complicado, yo de muchísimas películas que tengo sólo me ha ocurrido en unas pocas, y en esos casos hago lo que comento y funciona perfectamente, es algo manual, pero tampoco supone tanto trabajo...

Saludos.

[AARON8888]

Hola, Jacqlittlte

Me tengo que quitar el sombrero y felicitarte por encontrar una solución viable.
Felicidades de nuevo.
Está claro que el programa no es capaz de seguir buscando en las páginas de FilmAffinity, pinchando en "Buscar más", sería la solución lógica ya que viene en la ventana de la búsqueda del script, por algo será. Pero supongo que esto depende solo y exclusivamente del que creó la última versión del programa, sr. Mickael Vanneufville. Esperaremos a la próxima versión a ver si ya solucionó este problema. Sería para quitarse el sombrero también.

PD: AUPAKEPA, ya tienes una solución de nuestro colega Jacqlittle, algo es algo, mejor que meter todos los datos campo a campo pinchando "copiar" y "pegar" de la web al programa.

Arriba colegas, y saludos de un cinéfilo.

[AUPAKEPA]

MUCHÍSIMAS GRACIAS
PERFECTO

[jacqlittle]

De nada, para eso estamos, para compartir unos con otros lo que sepamos y ayudarnos en lo que podamos...

Saludos.

[antp]

I am not sure to understand what is said above, but if there is an update for the script someone could send it to me? So I can include it on the server.

[AARON8888]

Hello antp

I think nothing to be declared in order to update the script.

I read AUPAKEPA message some days ago and I realised that he had same question as me.

The thing is you cannot see all titles from website FilmAffinity when you try to search a common title. This is not often situation, since not so many tittles are common.

For example, if you try to find title Attack! (1.956), it is only running all titles for page 1 from FilmAffinity (ES), and not page 2 or 3 ... despite you have windows option "Find more" with no fuction.

Anyhow, our colleage jacqlittle suggested to insert URL tittle from FilmAffinity in order to catch all info to AMC, which was successfully.

I thought it is not for fault script, I think this should be considered into next AMC version, doesn´t it?

Regards.

[antp]

I think this should be considered into next AMC version, doesn´t it?

What should be considered? The page numbers? With the "find more" button it is possible to go to the next page, but the script has to provide the URL for the next page and handle that propetly, maybe it is not the case of this script?

[AARON8888]

Hi, antp
I agree with you. This case is not for this script. It should locate to other post, although I do not know which one.

Regards.

[juliojs]

Buenas!

Antes de nada disculpas a AARON8888 por no contestar a los privados, pero es que no los he visto hasta ahora... XD

Efectivamente hay veces que el script no encuentra la película si ésta tiene un nombre muy genérico, ya que aparece sepultada entre los resultados y el script sólo muestra los 20 primeros.

Hasta ahora pensaba que era una limitación del script... pero no, algo se había roto durante el cambio de diseño de la web... por suerte, creo que ya está arreglado!!

Saludos!

-----------------------------------------------------------------------------
@antp:
There was a bug in the script since the web design changed but we didn't notice it. Now it should work as spected, let a couple of users to confirm if it's working for them and then update it on the server if you like.
Thank you for your work, it's really an amazing application!!!

Code: Select all

(*************************************************** 

Ant Movie Catalog importation script 
www.antp.be/software/moviecatalog/ 

[Infos] 
Authors=aviloria (aviloria@yahoo.com) modded by: rodpedja (rodpedja@gmail.com), kreti (bisoft@hotmail.com), MrK, gilistico, juliojs 
Title=FilmAffinity (ES) 
Description=Movie importation script for FilmAffinity Spain 
Site=http://www.filmaffinity.com 
Language=ES 
Version=2.66 
Requires=3.5.0 
Comments=Updated to 2013/04/16 version of the web-page. Added an option to choose Actor list format (ActorsInALine). 
License=The source code of the script can be used in another program only if full credits to script author and a link to Ant Movie Catalog website are given in the About box or in the documentation of the program.| 
GetInfo=1 
RequiresMovies=1 

[Options] 
DontAsk=0|0|1=Método rápido: No te pregunta el titulo al principio, ni te pide confirmar si sólo hay un resultado|0=Método lento: Confirmas la información manualmente 
ActorsInALine=0|0|1=Actores separados por comas|0=Actores en lineas independientes 

[Parameters] 

***************************************************) 

program FilmAffinity; 
const 
   BaseURL = 'http://www.filmaffinity.com'; 
var 
   MovieName: string; 
   MovieURL: string; 
    
//------------------------------------------------------------------------------------ 

function FindLine(Pattern: string; List: TStringList; StartAt: Integer): Integer; 
var 
   i: Integer; 
begin 
   Result := -1; 
   if StartAt < 0 then StartAt := 0; 
   for i := StartAt to List.Count-1 do 
      if Pos(Pattern, List.GetString(i)) <> 0 then 
      begin 
         Result := i; 
         Break; 
      end; 
end; 

//------------------------------------------------------------------------------------ 

function TextBetween(S: string; StartTag: string; EndTag: string): string; 
var 
   ini, fin: Integer; 
begin 
   Result := ''; 
   ini := Pos(StartTag, S); 
   if ini <> 0 then 
   begin 
      ini := ini + Length(StartTag); 
      fin := Pos(EndTag, S); 
      if (fin <> 0) and (fin > ini) then 
      begin 
         Result := Copy(S, ini, fin - ini); 
      end; 
   end; 
end; 

//------------------------------------------------------------------------------------ 

function DeleteTags(S: string): string; 
var 
   n, len, tag: Integer; 
   c, p: char; 
begin 
   HTMLDecode(S); 
   len    := Length(S); 
   tag    := 0; 
   p      := ' '; 
   Result := ''; 
   for n := 1 to len do 
   begin 
      c := Copy(S,n,1); 

      // Eliminamos los tabuladores 
      if c = #9 then c := ' '; 

      // Los espacios redundantes no se procesan 
      if (c <> ' ') or (p <> ' ') then 
      begin 
         // Eliminamos los tags de HTML 
         if tag = 0 then 
         begin 
            if c <> '<' then 
            begin 
               Result := Result + c; 
               p := c; 
            end 
            else tag := 1; 
         end 
         else if c = '>' then tag := 0; 
      end; 
   end 
   if p = ' ' then Result := Copy(Result, 1, Length(Result) - 1); 
end; 

//------------------------------------------------------------------------------------ 

procedure AnalyzePage(Address: string); 
var 
   Page: TStringList; 
   LineNr: Integer; 
   Line: string; 
   Count: Integer; 
   MovieTitle, MovieAddress: string; 

begin 
   Count := 0; 
   Page  := TStringList.Create; 
   Page.Text := GetPage(Address); 
   PickTreeClear; 

   // Get how much search results have been found 
   LineNr := FindLine('</strong> resultados.</div>', Page, 0); 
   if LineNr <> -1 then 
   begin 
      Line  := Page.GetString(LineNr); 
      Count := StrToInt(TextBetween(Line, '<div style="text-align:right;"><strong>', '</strong> resultados.</div>'), 0); 
   end; 

   // Add the results to the PickTree 
   if Count = 0 then 
      ShowMessage('No se ha encontrado ningún registro') 
   else 
   begin 
      LineNr := 0; 
      while true do 
      begin 
         LineNr := FindLine('<div class="mc-title"><a href="', Page, LineNr + 1); 
         if LineNr = -1 then 
         begin 
            LineNr := FindLine('siguientes >>', Page, 0);
            if LineNr = -1 then
               break;
            Line      := Page.GetString(LineNr);
            Page.Text := GetPage('http://www.filmaffinity.com/es/search.php' + TextBetween(Line, '<a href="search.php', '"><div class="')); 
            LineNr    := 0; 
            continue; 
         end; 

         Line         := Page.GetString(LineNr); 
         MovieAddress := TextBetween(Line, '<div class="mc-title"><a href="', '.html">') + '.html'; 
          
         MovieTitle   := DeleteTags(TextBetween(Line, '.html">', '<img src="')); 

         if (Length(MovieAddress) <> 0) and (Length(MovieTitle) <> 0) then 
            PickTreeAdd(MovieTitle, BaseURL + MovieAddress); 
      end; 

      if ((Count = 1) and (GetOption('DontAsk') = 1)) or PickTreeExec(Address) then 
         AnalyzeMoviePage(Address); 
   end; 
   Page.Free; 
end; 

//------------------------------------------------------------------------------------ 

procedure AnalyzeMoviePage(Address: string); 
var 
   Page: TStringList; 
   LineNr, LineInc: Integer; 
   Line: string; 
   Item: string; 
   Comments: string; 

begin 
   Comments := ''; 

   // URL 
   SetField(fieldURL, Address); 

   Page := TStringList.Create; 
   Page.Text := GetPage(Address); 

   // Translated Title 
   LineNr := FindLine('<h1 id="main-title">', Page, 0); 
   Line := Page.GetString(LineNr); 
   Item := DeleteTags(TextBetween(Line, '<h1 id="main-title">', '</h1>')); 
   SetField(fieldTranslatedTitle, Item); 

   // Picture 
   LineNr := FindLine('http://pics.filmaffinity.com/', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr); 
      Item := TextBetween(Line, '<a class="lightbox" href="', '" title="'); 
      if Length(Item) = 0 then 
         Item := TextBetween(Line, '" src="', '"></a>'); 
      GetPicture(Item); 
   end; 

   // Rating 
   LineNr := FindLine('<div id="movie-rat-avg">', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(Line); 
      SetField(fieldRating, StringReplace(Item, ',', '.')); 
   end; 

   // Original Title 
   LineNr := FindLine('<dt>Título original</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>')); 
      SetField(fieldOriginalTitle, Item); 
   end; 

   // Year 
   LineNr := FindLine('<dt>Año</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>')); 
      SetField(fieldYear, Item); 
   end; 

   // Length 
   LineNr := FindLine('<dt>Duración</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(TextBetween(Line, '<dd>', 'min.</dd>')); 
      SetField(fieldLength, Item); 
   end; 

   // Country 
   LineNr := FindLine('<dt>País</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(TextBetween(Line, 'title="', '" border')); 
      SetField(fieldCountry, Item); 
   end; 
  
   // Director 
   LineNr := FindLine('<dt>Director</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>')); 
      SetField(fieldDirector, Item); 
   end; 

   // Script writer 
   LineNr := FindLine('<dt>Guión</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := TextBetween(Line, '<dd>', '</dd>'); 
      Comments := Comments + 'Guión: ' + Item + #13#10 + #13#10; 
   end; 

   // Composer 
   LineNr := FindLine('<dt>Música</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := TextBetween(Line, '<dd>', '</dd>'); 
      Comments := Comments + 'Música: ' + Item + #13#10 + #13#10; 
   end; 

   // Photography 
   LineNr := FindLine('<dt>Fotografía</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := TextBetween(Line, '<dd>', '</dd>'); 
      Comments := Comments + 'Fotografía: ' + Item + #13#10 + #13#10; 
   end; 

   // Actors 
   LineNr := FindLine('<dt>Reparto</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>')); 
      if GetOption('ActorsInALine') = 0 then Item := StringReplace(Item, ', ', #13#10); 
      SetField(fieldActors, Item); 
   end; 

   // Productor 
   LineNr := FindLine('<dt>Productora</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>')); 
      SetField(fieldProducer, Item); 
   end; 

   // Category 
   LineNr := FindLine('<dt>Género</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 2); 
      Item := DeleteTags(Line); 
      Item := StringReplace(Item, ' | ', ', '); 
      Item := StringReplace(Item, '. ', ', '); 
      SetField(fieldCategory, Item); 
   end; 

   // Official Webpage 
   LineNr := FindLine('<dt>Web Oficial</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(TextBetween(Line, ' href="', '">')); 
      Comments := Comments + 'Web oficial: ' + Item + #13#10 + #13#10; 
   end; 

   // Synopsis 
   LineNr := FindLine('<dt>Sinopsis</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Line := Page.GetString(LineNr + 1); 
      Item := DeleteTags(Line); 
      SetField(fieldDescription, Item); 
   end; 

   // Awards 
   LineNr := FindLine('<dt>Premios</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      LineNr   := LineNr + 1; 
      Line     := Page.GetString(LineNr); 
      Comments := Comments + 'Premios: ' + #13#10; 
      while Pos ('</dd>', Line) = 0 do 
      begin 
         if Pos ('<span id="show-all-awards">', Line) = 0 then 
         begin 
            Item := DeleteTags(Line); 
            if (Length(Item) <> 0) then 
            begin 
               Comments := Comments + '  - ' + Item + #13#10; 
            end; 
         end; 
         LineNr := LineNr + 1; 
         Line   := Page.GetString(LineNr); 
      end; 
      Comments := Comments + #13#10; 
   end; 

   // Critic 
   LineNr := FindLine('<dt>Críticas</dt>', Page, LineNr); 
   if LineNr <> -1 then 
   begin 
      Comments := Comments + 'Críticas: ' + #13#10 + #13#10; 
      LineNr   := FindLine('<div class="pro-review">', Page, LineNr + 1); 
      while LineNr <> -1 do 
      begin 
         LineNr  := LineNr + 1; 
         Line    := Page.GetString(LineNr); 
         LineInc := 2; 
         if Pos ('<a title="Leer crítica completa" href=', Line) <> 0 then 
         begin 
           LineNr  := LineNr + 1; 
           Line    := Page.GetString(LineNr); 
           LineInc := 3; 
         end; 
         Item := DeleteTags(Line); 
         if (Length(Item) <> 0) then 
         begin 
            Comments := Comments + Item + #13#10; 
            LineNr := LineNr + LineInc; 
            Line := Page.GetString(LineNr); 
            Item := DeleteTags(Line); 
            if (Length(Item) <> 0) then 
            begin 
               Comments := Comments + Item + #13#10; 
            end; 
            Comments := Comments + '________________________________________' + #13#10 + #13#10; 
         end; 
         LineNr := FindLine('<div class="pro-review">', Page, LineNr + 1); 
      end; 
   end; 

   HTMLDecode(Comments); 
   SetField(fieldComments, Comments); 
end; 

//------------------------------------------------------------------------------------ 

begin 
   if (CheckVersion(3,5,0) = false) then 
   begin 
      ShowMessage('Se requiere Ant Movie Catalog versión 3.5 o superior'); 
      exit; 
   end; 

   MovieName := GetField(fieldOriginalTitle); 
   if Length(MovieName) = 0 then 
      MovieName := GetField(fieldTranslatedTitle); 

   if GetOption('DontAsk') = 0 then 
      Input('FilmAffinity', 'Pelicula:', MovieName); 

   if Pos('filmaffinity.com', MovieName) > 0 then 
      AnalyzeMoviePage(MovieName) 
   else 
      AnalyzePage(BaseURL +'/es/search.php?stext=' + UrlEncode(MovieName) + '&stype=Title'); 
end. 

[AARON8888]

Gracias juliojs y antp por todo.

Sois magníficos. XD
Lo voy a probar a ver cómo funciona.

Saludos.
--------------------------------------------
Thanks, juliojs and antp

Both of you are great. XD
I will test myself later on.

Greetings.

[antp]

@antp:
There was a bug in the script since the web design changed but we didn't notice it. Now it should work as spected, let a couple of users to confirm if it's working for them and then update it on the server if you like.
Thank you for your work, it's really an amazing application!!!

Thanks, I'll wait for confirmation from others and then I'll put it on the server