[FR] Énorme aide pour Template...

[Guest]

Hello,

Je viens de découvrir le forum accompagnant Ant, et je suis rester bouche bée devant la template qu'un des forumeur a réalisée.
Etant nul en programmation internet, je n'ai rien compris comment j'aurais pu modifier celle-ci, j'ai donc en effets modifier l'image originale.

Je vous demande donc si une personne pourrais m'aider a réaliser cette modification...

tout débord voici l'image :



Je désire donc y soumettre quelques modifications...

Tout débord supprimer la classement par genre des films, ainsi que le moteur de recherche.
Ensuite, supprimer les numéros de films et classer ceux-ci par ordre alphabétique.

Je souhaite également garder la fonctionnalité, qui permet, lors d'un clic sur le titre du film, d'ouvrir une fenêtre affichant ainsi les informations concernant le film, mais cependant avec quelques modifications...

-------------------------------------------------------------------------------------

Titre - Note (étoiles)

Genre :
Production : Pays / Année
Réalisateur :

Acteurs :

Description :

Infos DivX

Durée :
Nombre de CD :
Codec :
Son : Type / (128) kpbs

-------------------------------------------------------------------------------------

Voilà, y a t'il une personne qui pourais m'aider à réaliser ce type de template...

Merci

[Okipa]

Aidez moi svp...

j'ai essayer de regarder ce que je pouvais modifier pour obtenir ca, mais ca ne marche plus du tt...

[antp]

je voudrais bien t'aider, mais je ne sais pas trop comment fonctionne ce template, et en plus j'ai pas énormément le temps de me plonger là dedans
Enfin si j'ai le temps et que j'oublie pas, j'y jetterai un coup d'oeil demain.
C'est quel template exactement au fait ?

[Okipa]

c'est celle qu'un forumer a develloper, mais je ne capte rien...

viewtopic.php?t=287

merci ca serai cool de ta part...

@+

[Okipa]

isn't anybody to help me...???

[Vince]

Bon une ame charitable pour t'aider.. et en french en sus

1. Telecharge le fichier fournit par 'Willspo' concernant ce template

2. Extrait dans un repertoire de ton choix ; je prendrais comme exemple ici le repertoire "TEST" sur "C:\" soit "C:\TEST"

Pour info :
L'index.html est dans le rep. "c:\TEST"a la racine.
Tu trouveras egalement un fichier "MOVIES.XML " dans le rep. "c:\TEST\DATA\" (verifie quand meme ...!!)

3. Renomme ton fichier "c:\TEST\DATA\MOVIES.XML" en "c:\TEST\DATA\TEMPLATEWILLSPO.HTML" (par exemple!!)
Ensuite deplace le fichier c:\TEST\DATA\TEMPLATEWILLSPO.HTML ainsi renommé dans ton repertoire template ; par exemple dans le rep. des templates par defaut de Ant Movies catalog soit "C:\Program Files\BuyPin Software\Ant Movie Catalog\Templates"

4. Ouvres Ant software avec ta base de divX actuelle

5. Faire "Fichier/Exporter"

6. Choisir le format "HTML"

7. Utilise le fichier "C:\Program Files\BuyPin Software\Ant Movie Catalog\Templates\TEMPLATEWILLSPO.HTML " comme script (au lieu de celui que tu utilisais avant)

8. Cocher sur la case "Copier les images vers le meme repertoire que le fichier exporté"

9. Clique sur "Exporter" , et choisit (tres important ici) comme nom de fichier de destination "c:\TEST\DATA\MOVIES.XML"

( Je le rappelles encore, mais tout depend de ton repertoire de départ ou tu a decompressé le fichier .zip de willspo )

Voila !!!
Admire maintenant ton site en lancant l'index.html de "c:\TEST\DATA\index.html" et tout devrait fonctionner

[antp]

Bon une ame charitable pour t'aider.. et en french en sus

En fait il voulait modifier le template

[Okipa]

oui , j'ai réussi a la faire fonctionner, mais c la modifier que je n'arrive pas...

[angemort]

Hello

Quelqu'un pourrais me dire ou l'on peut télécharger les fichiers de base de Willspo ?
Car dans le topic en anglais les liens que je trouve sont en 404, snif snif

Merci

[antp]

le template dont on parle est dans le fichier "xslt template.zip" (ou quelque chose du genre) fourni avec le programme, dans le dossier Templates

[angemort]

Thanks je vais essayer

[Guest]

bien le bonsoir...
juste un truc. Je ne m'y connais pas plus qu'angemort en programmation, mais je voudrais faire une toute petite modif au template de willspo : garder sa toute belle fenêtre dans mon explorateur... et ne plus l'avoir en plein écran : j'arrive pas à en sortir à moins d'éclater le processus, ce qui me parait quelque peu barbare...
merci !

[antp]

Si c'est quand on lance le truc via le fichier index.hta, il suffit dans ce fichier index.hta de supprimer les lignes suivantes du début du fichier:
windowstate="maximize"
caption="no"
border="none"

[maxou545]

ou bien tu fait alt+F4 pour en sortir ....

[HarryCover]

Vi "ALT + F4" ça marche à tous les coups

Quelque soit le prog d'ailleurs

[Paramount Jay]

Bien bon ok, comme ça fait longtemps que tu demandes réponse à ta question et que j'avais quelques minutes, je me suis un peu penché dessus, voici donc le script xsl modifié selon tes desiderata:

Code: Select all

<?xml version="1.0" encoding="ISO-8859-1" ?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
		xmlns:msxsl="urn:schemas-microsoft-com:xslt"
		exclude-result-prefixes="msxsl"
		version="1.0">
	<xsl:output omit-xml-declaration="yes" indent="yes" />
	<xsl:preserve-space elements="all"/>
	<xsl:param name="selected_category" select="'All'" />
	<xsl:param name="sort_by" select="'title'" />
	<xsl:param name="sort_data_type" select="'text'" />
	<xsl:param name="sort_order" select="'ascending'" />
	<xsl:param name="mode" select="'normal_view'" />
	<xsl:param name="movie_number" select="'1'" />
	<xsl:param name="search" select="'false'" />
	<xsl:param name="search_string" select="''" />
	<xsl:param name="application_type" select="'html'" />
	
	<xsl:param name="show_category" select="'true'" />
	<xsl:param name="show_country" select="'true'" />
	<xsl:param name="show_director" select="'true'" />
	<xsl:param name="show_date" select="'true'" />
	<xsl:param name="show_year" select="'true'" />
	
	<xsl:template match="/"> 
			<xsl:choose>
				<xsl:when test="$mode = 'normal_view'">
					<table cellpadding="0" cellspacing="0" border="0" id="mainTable" height="100%">
					<tr><td valign="top">
						<xsl:apply-templates select="//movies" mode="normal_view" />
					</td></tr>
					</table>
				</xsl:when>
				<xsl:when test="$mode = 'info_view'">
					<xsl:apply-templates select="//movies" mode="info_view" />
				</xsl:when>
			</xsl:choose>
	</xsl:template>
	
	<xsl:template match="movies" mode="create_topbar">
		<a href="javascript:showCategory('All')">
			<xsl:attribute name="class">
				<xsl:choose>
					<xsl:when test="$selected_category='All'">
						filterSelected
					</xsl:when>
					<xsl:otherwise>
						filter
					</xsl:otherwise>
				</xsl:choose>
			</xsl:attribute>
			Aucun
		</a><br />
			<xsl:variable name="single_categories">
				<xsl:apply-templates select="movie/category" mode="find_categories" />
			</xsl:variable>
			<xsl:for-each select="msxsl:node-set($single_categories)//subcategory[not(. = preceding::subcategory)]">
				<xsl:sort select="." data-type="text" />
				<a>
					<xsl:attribute name="href">
						javascript:showCategory('<xsl:value-of select="." />')
					</xsl:attribute>
					<xsl:attribute name="class">
					<xsl:choose>
						<xsl:when test=". = $selected_category">
							filterSelected
						</xsl:when>
						<xsl:otherwise>
							filter
						</xsl:otherwise>
					</xsl:choose>
					</xsl:attribute>
					<xsl:value-of select="." />
				</a><br />
			</xsl:for-each>
	</xsl:template>
	
	<xsl:template match="movies" mode="normal_view">
		<xsl:param name="upper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZÅÄÖ'" />
		<xsl:param name="lower" select="'abcdefghijklmnopqrstuvwxyzåäö'" />
		<table cellspacing="0" class="movieList">
			<thead>
				<th><a href="javascript:sortBy('title','text')" class="tHead">Titre</a></th>
				<th><a href="javascript:sortBy('rating','text')" class="tHead">Note</a></th>
				<xsl:if test="$show_director = 'true'">
				<th><a href="javascript:sortBy('director','text')" class="tHead">Réalisateur</a></th>
				</xsl:if>
				<xsl:if test="$show_category = 'true'">
				<th><a href="javascript:sortBy('category','text')" class="tHead">Catégorie</a></th>
				</xsl:if>
				<xsl:if test="$show_country = 'true'">
				<th><a href="javascript:sortBy('country','text')" class="tHead">Pays</a></th>
				</xsl:if>
				<xsl:if test="$show_year = 'true'">
				<th><a href="javascript:sortBy('year','text')" class="tHead">Année</a></th>
				</xsl:if>
			</thead>
			<xsl:choose>
				<xsl:when test="$search = 'true'">
					<xsl:apply-templates select="movie[contains(translate(actors, $upper, $lower), $search_string) or 
														contains(translate(director, $upper, $lower), $search_string) or
														contains(translate(title, $upper, $lower), $search_string)
														]" mode="normal_view">
						<xsl:sort select="*[name() = $sort_by]" order="{$sort_order}" data-type="{$sort_data_type}" />
					</xsl:apply-templates>
				</xsl:when>
				<xsl:otherwise>
					<xsl:apply-templates select="movie[contains(./category, $selected_category) or $selected_category='All']" mode="normal_view">
						<xsl:sort select="*[name() = $sort_by]" order="{$sort_order}" data-type="{$sort_data_type}" />
					</xsl:apply-templates>
				</xsl:otherwise>
			</xsl:choose>
		</table>
	</xsl:template>
	
	<xsl:template match="movie" mode="normal_view">	
		<tr onmouseover="mouseOverTR(this)" onmouseout="mouseOutTR(this)" class="movieList">
			<xsl:attribute name="onclick">
				showMovieInfo(<xsl:value-of select="number" />);
			</xsl:attribute>
			<td width="100%" class="movieList">
				<span class="title" id="col_title">
				<xsl:value-of select="substring-before( title[contains(., '(')], '(' )" />
				<xsl:value-of select="title[not(contains( ., '(' ))]" />
				 (<xsl:value-of select="number" />)
				</span>
			</td>
			<td class="movieList">
				<img src="images/blank.gif">
					<xsl:attribute name="style">
						width: 52px; height: 12px; border: none;
						filter:progid:DXImageTransform.Microsoft.AlphaImageLoader(
						src='images/<xsl:value-of select="rating" />.png', sizingMethod='scale') 
					</xsl:attribute>
				</img>
			</td>
			<xsl:if test="$show_director = 'true'">
				<td class="movieList" >
					<span id="col_director">
						<xsl:value-of select="director" />
					</span>
				</td>
			</xsl:if>
			<xsl:if test="$show_category = 'true'">
				<td class="movieList">
					<span id="col_category">
						<xsl:value-of select="category" />
					</span>
				</td>
			</xsl:if>
			<xsl:if test="$show_country = 'true'">
				<td class="movieList">
					<span id="col_country">
						<xsl:value-of select="country" />
					</span>
				</td>
			</xsl:if>
			<xsl:if test="$show_year = 'true'">
				<td class="movieList">
					<span id="col_year">
						<xsl:value-of select="year" />
					</span>
				</td>
			</xsl:if>
		</tr>
	</xsl:template>
	
	<xsl:template match="movies" mode="info_view">
		<div class="windowContent">
		<table class="infoViewTable" height="100%" width="100%" cellpadding="0" cellspacing="0" border="0">
			<xsl:apply-templates select="movie[number=$movie_number]" mode="info_view" />	
		</table>
		</div>
	</xsl:template>
	
	<xsl:template match="movie" mode="info_view">
		<tr>
		<td class="infoViewTable" valign="top" width="333">
			<img class="largePicture">
				<xsl:attribute name="src">
					data/<xsl:value-of select="picture" />
				</xsl:attribute>
			</img>
		</td>
		<td valign="top" class="infoViewTable">
		<div class="infoViewText">
			<p class="infoView">
			<span class="largeTitle">
				<xsl:value-of select="title" />
			</span>
			<img src="images/blank.gif">
				<xsl:attribute name="style">
					width: 52px; height: 12px; border: none;
					filter:progid:DXImageTransform.Microsoft.AlphaImageLoader(
					src='images/<xsl:value-of select="rating" />.png', sizingMethod='scale') 
				</xsl:attribute>
			</img>
			</p><p class="infoView">
			<b>Catégorie:</b> <xsl:value-of select="category" />
			<br class="infoViewTable" />
			<b>Production:</b> <xsl:value-of select="country" />, <xsl:value-of select="year" />
			<br class="infoViewTable" />
			<b>Durée:</b> <xsl:value-of select="length" />
			<br class="infoViewTable" />
			<b>Réalisateur:</b> <xsl:value-of select="director" />
			</p><p class="infoView">
			<b>Acteurs:</b><br />
			<xsl:call-template name="commas_to_br">
				<xsl:with-param name="src" select="actors" />
			</xsl:call-template>
			</p>
			<p class="infoView">
			<b>Description:</b><br />
			<xsl:call-template name="html_br">
				<xsl:with-param name="src" select="description" />
			</xsl:call-template>
			</p><p class="infoView">
			<b>Infos DivX</b>
			<br class="infoViewTable" />
			  Nombre de CD: <xsl:value-of select="disks" />
			<br class="infoViewTable" />
			  Codec: <xsl:value-of select="videoformat" />
			<br class="infoViewTable" />
			  Son: <xsl:value-of select="soundformat" /> / <xsl:value-of select="audiobitrate" /> Kbps
			<br class="infoViewTable" />
			</p>
		</div>
		<p align="right" style="margin-top:10px;padding:0px;">
		<a class="button" href="javascript:hideMovieInfo()">Fermer la fenêtre</a>
		<xsl:if test="$application_type = 'hta'">
			<a class="button">
				<xsl:attribute name="href">
					javascript:showPlayDialog(
						<xsl:value-of select="number" />,
						'<xsl:value-of select="media" />'
					)
				</xsl:attribute>
				Jouer
			</a>
		</xsl:if>
		</p>
		</td>
		</tr>
	</xsl:template>
	
	<xsl:template name="commas_to_br">
		<xsl:param name="src" />
		<xsl:choose> 
		   <xsl:when test="contains($src, ',')"> 
			   <xsl:value-of select="substring-before($src, ',')" />
				<br />
				<xsl:call-template name="commas_to_br">
					<xsl:with-param name="src" select="substring-after($src, ',')" />
				</xsl:call-template> 
		   </xsl:when> 
		   <xsl:otherwise> 
			  <xsl:value-of select="$src" /> 
		   </xsl:otherwise> 
		</xsl:choose>
	</xsl:template>

   	<xsl:template name="html_br">
		<xsl:param name="src" />
		<xsl:choose> 
		   <xsl:when test="contains($src, '<br />')"> 
			   <xsl:value-of select="substring-before($src, '<br />')" />
				<br />
				<xsl:call-template name="html_br">
					<xsl:with-param name="src" select="substring-after($src, '<br />')" />
				</xsl:call-template> 
		   </xsl:when> 
		   <xsl:otherwise> 
			  <xsl:value-of select="$src" /> 
		   </xsl:otherwise> 
		</xsl:choose>
	</xsl:template>

	<xsl:template match="category" mode="find_categories">
		<xsl:call-template name="split_categories">
			<xsl:with-param name="src" select="." />
		</xsl:call-template>
	</xsl:template>
			
	<xsl:template name="split_categories">
		<xsl:param name="src" />
		<xsl:param name="delimiter" select="'/'" />
		<xsl:choose>
			<xsl:when test="contains($src, $delimiter)">
				<subcategory><xsl:value-of select="normalize-space(substring-before($src, $delimiter))" /></subcategory>
				<xsl:call-template name="split_categories">
					<xsl:with-param name="src" select="substring-after($src, $delimiter)" />
				</xsl:call-template>
			</xsl:when>
			<xsl:when test="$src != ''">
				<subcategory><xsl:value-of select="normalize-space($src)" /></subcategory>
			</xsl:when>
		</xsl:choose>
	</xsl:template>	
</xsl:stylesheet>

... ainsi que le template d'exportation en xml:

Code: Select all

<?xml version="1.0" encoding="ISO-8859-1" ?>
<movies>
	$$ITEM_BEGIN
	<movie>
		<number>$$ITEM_NUMBER</number>
		<date>$$ITEM_DATEADD</date>
		<media>$$ITEM_TYPE</media>
		<title><![CDATA[$$ITEM_FORMATTEDTITLE2]]></title>
		<year>$$ITEM_YEAR</year>
		<length>$$ITEM_LENGTH</length>
		<category>$$ITEM_CATEGORY</category>
		<director><![CDATA[$$ITEM_DIRECTOR]]></director>
		<description><![CDATA[$$ITEM_DESCRIPTION]]></description>
 	  	<producer><![CDATA[$$ITEM_PRODUCER]]></producer>
   		<picture>$$ITEM_PICTUREFILENAME</picture>
   		<actors><![CDATA[$$ITEM_ACTORS]]></actors>
   		<rating>$$ITEM_RATING</rating>
   		<borrower><![CDATA[$$ITEM_BORROWER]]></borrower>
   		<country>$$ITEM_COUNTRY</country>
      <disks>$$ITEM_DISKS</disks>
      <videoformat>$$ITEM_VIDEOFORMAT</videoformat>
      <soundformat>$$ITEM_AUDIOFORMAT</soundformat>
      <audiobitrate>$$ITEM_AUDIOBITRATE</audiobitrate>
	</movie>
	$$ITEM_END
</movies>

Voilà! Qu'est ce qu'on dit?

[Guest]

tu démontes, je viens de voir ce que tu avais fait et c'est exactement ce que je voulais faire...

Je crois bien que l'on dit merci Paramount Jay

@+ et encore merci

[Okipa]

juste, ya pas moyen de virer les numéros a coté des titres de film, car j'aime pas trop...???

et aussi...je suis exigent, mais je souhaiterai en mettre 25 par page...c'est possible...????

encore merci de ton aide précieuse...

[Copycat]

Hello !

Heu j'ai beau importer mes films comme indiquer mais je n'ai que le fenetre de recherche comme si mon movie.xml était vide...

Une idée de quoi ça peut venir ?

Merci

[Okipa]

bah as tu bien modifié le code de la page avant de faire ca et as tu bien lancé le bon fichier...

sinon personne sait comment faire pour virer les numéros et affiché la liste en plusieurs pages avec 25 films par page?

merci