antp.be forum

Code: Select all

// GETINFO SCRIPTING
// Imports Turkish Titles from beyazperde.com

(***************************************************
 *  Movie importation script for:                  *
 *      IMDB (US), http://us.imdb.com              *
 *                                                 *
 *  (c) 2002 Antoine Potten    antoine@buypin.com  *
 *  Improvements made by Danny Falkov              *
 *  Improvements made by Kai Blankenhorn           *
 *                                                 *
 *  For use with Ant Movie Catalog 3.4.0           *
 *  www.ant.be.tf/moviecatalog ··· www.buypin.com  *
 *                                                 *
 *  The source code of the script can be used in   *
 *  another program only if full credits to        *
 *  script author and a link to Ant Movie Catalog  *
 *  website are given in the About box or in       *
 *  the documentation of the program               *
 ***************************************************)

program TurkishTitle;
var
  MovieName: string;

function FindLine(Pattern: string; List: TStringList; StartAt: Integer): Integer;
var
  i: Integer;
begin
  result := -1;
  if StartAt < 0 then
    StartAt := 0;
  for i := StartAt to List.Count-1 do
    if Pos(Pattern, List.GetString(i)) <> 0 then
    begin
      result := i;
      Break;
    end;
end;

procedure AnalyzePage(Address: string);
var
  Page: TStringList;
  LineNr: Integer;
begin
  Page := TStringList.Create;
  Page.Text := GetPage(Address);
  if pos('<title>beyazperde.com - H?zl? Arama', Page.Text) = 0 then
  begin
    SetField(fieldURL, Address);
    AnalyzeMoviePage(Page)
  end else
  begin
    PickTreeClear;
    LineNr := 0;
    LineNr := FindLine('<td class="metin3">Filmler</td>', Page, LineNr);
    if LineNr > -1 then
    begin
      PickTreeAdd('Filmler', '');
      AddMoviesTitles(Page, LineNr);
    end;
    if PickTreeExec(Address) then
      AnalyzePage(Address);
  end;
  Page.Free;
end;

procedure AnalyzeMoviePage(Page: TStringList);
var
  Line, Value, Value2, FullValue: string;
  LineNr: Integer;
  BeginPos, EndPos: Integer;
begin

  // Original Title & Year
  LineNr := FindLine('<title>beyazperde.com - ', Page, 0);
  Line := Page.GetString(LineNr);
  if LineNr > -1 then
  begin
    BeginPos := pos('<title>beyazperde.com - ', Line);
    if BeginPos > 0 then
      BeginPos := BeginPos + 24;
    EndPos := pos(' / ', Line);
    if EndPos = 0 then
      EndPos := Length(Line);
    Value := copy(Line, BeginPos, EndPos - BeginPos);
    HTMLDecode(Value);
    SetField(fieldTranslatedTitle, Value);
  end;
  SetField(fieldOriginalTitle, '');
  SetField(fieldUrl, '');
  
  DisplayResults;
end;

procedure AddMoviesTitles(Page: TStringList; var LineNr: Integer);
var
  Line: string;
  MovieTitle, MovieAddress: string;
  StartPos: Integer;
  TempPos: Integer;
begin
  repeat
    LineNr := LineNr + 1;
    Line := Page.GetString(LineNr);
    TempPos := pos('<img src="', Line);

    if TempPos < 1 then
    begin
      StartPos := pos('<a href="', Line);
      if StartPos > 0 then
      begin
        Startpos := Startpos + 9;
        MovieAddress := copy(Line, StartPos, pos('" class=metin2>', Line) - StartPos);
        StartPos := pos('<b>', Line) + 3;
        MovieTitle := copy(Line, StartPos, pos('</b>', Line) - StartPos);
        LineNr := LineNr + 1;
        Line := Page.GetString(LineNr);
        StartPos := pos('/ ', Line) + 2;
        MovieTitle := MovieTitle + ' - ' + copy(Line, StartPos, pos ('<br>', Line) - StartPos);
        HTMLDecode(Movietitle);
        PickTreeAdd(MovieTitle, 'http://www.beyazperde.com/' + MovieAddress);
      end;
    end;
  until pos('filmden', Line) > 0;
end;

begin
  if CheckVersion(3,4,0) then
  begin
    MovieName := GetField(fieldOriginalTitle);
//    if MovieName = '' then
//      MovieName := GetField(fieldTranslatedTitle);
    if Input('Turkish Title', 'Enter the original title of the movie:', MovieName) then
    begin
      AnalyzePage('http://www.beyazperde.com/hizliarama.asp?keyword='+UrlEncode(MovieName));
    end;
  end else
    ShowMessage('This script requires a newer version of Ant Movie Catalog (at least the version 3.4.0)');
end.