antp.be forum

Posted: **2020-01-12 08:54:35**

Mise à jour du script :

Ajout du Titre FR et Titre Original

Ajout Nom du Réalisateur

Ajout les Categories

Ajout Heure du Film en minute

Ajout de la Date de Sortie

Comment installer/remplacer le code existant :

Ouvrir Ant Movie Catalog

Outils

Scripting...

Sélectionner Allociné

Cliquer sur Editeur

CTRL-A sur le code pour tout selectionner

Coller le code ci-dessous pour le remplacer.

sauvegarder

Code: Select all

program Allocine_FR_v2;

uses
  StringUtils1, ScorEpioNCommonScript;

var
  MovieName: string;
  
const
  urlDomain = 'allocine.fr';
  urlAllocine = 'http://www.allocine.fr';
  urlFicheFilm = 'http://www.allocine.fr/film/fichefilm-';
  urlSearch = urlAllocine+'/recherche/1/?q=';

//------------------------------------------------------------------------------
// Remplace les virgules par des points							      Ajouté 2.06
//------------------------------------------------------------------------------

function convert_STF (ligne : String ) : Extended;
  var
    temp : Extended;
  begin
    ligne := FullTrim(ligne);
    temp := StrToFloat(ligne);
    if (ligne <> '0') and (temp = 0) then
    begin
      if pos(',',ligne) > 0 then
        ligne := stringreplace(ligne,',','.')
      else
      begin
        if pos('.',ligne) > 0 then
          ligne := stringreplace(ligne,'.',',');
      end;
      temp := StrToFloat(ligne);
    end;
    result := temp;
  end;
  
//------------------------------------------------------------------------------
// Fonction Puissance (mathématique)                      Ajouté 2.06
//------------------------------------------------------------------------------

function Power(base : extended ; puissance : integer): extended;
var
  temp : extended;
  i : integer;
begin
  temp := base;
  if puissance > 0 then
  begin
    for i:= 2 to puissance do
    temp := temp * base;
  end else
  begin
    if puissance = 0 then
    temp := 1
    else
    for i:= puissance to 0 do
    temp := temp / base;
  end;
  result := temp;
end;

//------------------------------------------------------------------------------
// Arrondi à la valeur décimale souhaité                 Ajouté 2.06
//------------------------------------------------------------------------------

function Arrondir(nombre : extended ; nbDecim : integer) : extended;
var
  p10 : extended;
  begin
    p10 := Power(10,nbDecim);
    result := round(nombre * p10) / p10;
  end;

//------------------------------------------------------------------------------
// Fonction pour récupérer les acteurs et leurs roles   Transféré 2.09 R_V
//------------------------------------------------------------------------------

function AllActors(Section : String) : string;
var
  Roles: Boolean;
  Page, Block, Value, Actors: string;
  T: TStringList;
begin
  Actors := '';
  Section := TextBetween(Section, '<div class="card person-card person-card-col">', '<div class="titlebar ">');
  Section := StringReplace(Section, '<div class="meta-sub light">', '');
  Section := StringReplace(Section, #13#10+'          </div>', '');
  Roles := GetOption('Roles acteurs') > 0;
   while Pos('<div class="card person-card person-card-col">', Section) > 0 do
    begin
      Block := TextBetween(Section, '<figure class="thumbnail ">', #13#10+'                    </div>');
      if Pos('<div class="section', Block) > 0 then
        Break;
      Section := RemainingText;
      if (Pos(UTF8Encode('Rôle : '), Block) > 0) then
        Value := TextBefore(Block, UTF8Encode('Rôle : '), '')
      else
        Value := Block;
      Value := CleanText(Value);
      if Value <> '' then
      begin
        if Actors <> '' then
          Actors := Actors + ', ';
        Actors := Actors + Value;
        if Roles then
          Actors := Actors + ' (' + CleanText(RemainingText) + ')';
      end
      if (CheckVersion(4,2,0) = True) and (GetOption('Extra : Photos des acteurs') = 1) then // Condition pour récupérer les photos des acteurs	Ajouté V2.08 R_V
      Extra_Photos_Acteurs(Block + '</div>'); // Récupération des photos des acteurs via la procédure Extra_Photos_Acteurs	Ajouté V2.08 R_V
    end;
    if GetOption('Acteurs') = 3 then
    begin
      while Pos('<div class="gd gd-xs-1 gd-s-2 md-table-row ">', Section) > 0 do
      begin
        Block := TextBefore(Section, '</div>', '');
        if Pos('<div class="section', Block) > 0 then
        Break;
        Section := RemainingText;
        if Pos('</span>', Block) > 0 then
        begin
          Value := TextAfter(Block, '</span>');
          Value := CleanText(Value);
          if Value <> '' then
          begin
              Actors := Actors + ', ' + Value;
              if Roles then
              begin
                Value := TextBefore(Block, '</span>', '');
                Actors := Actors + ' (' + CleanText(Value) + ')';
              end;
          end;
        end;
      end;
    end;
  result := Actors;
end;

//------------------------------------------------------------------------------
// IMPORTE LES PHOTOS DU FILM COMME EXTRAS              Ajouté 2.07 R_V
//------------------------------------------------------------------------------

procedure Extra_Photos_Film(Value : String);
Var
  AdressePhoto, AdresseExtra, Comparaison : String;
  BeginPos, idx, NbrExtra, i : Integer;

  begin
            NbrExtra := GetExtraCount;
            if Pos('data-src="', Value) > 0 then  // s'assure que l'adresse de l'image existe
              begin
              BeginPos := Pos('data-src="', Value);
              repeat
              delete(Value, 1, BeginPos+4);
              AdressePhoto := FullTrim(findInfo('src="', '"', Value,'0'));
              if AdressePhoto <> '' then  // s'assure que l'adresse de l'image n'est pas vide
                begin
                For i := 0 to NbrExtra-1 do  //  Début boucle pour comparer les adresses des images déja dans la base avec celles du site
                if GetExtraField(i, eCategory) = 'Photos du film' then  // ne compare que les extras ayant pour catégorie : 'Photos du film'
                  begin
                    AdresseExtra := GetExtraField(i , extraFieldURL);
                    if (AdresseExtra = AdressePhoto) then
                      begin
                      Comparaison := 'OK';
                      Break;
                      end else
                      begin
                      Comparaison := 'KO';
                      end;                  // fin boucle comparaison
                  end else
                  Comparaison := 'KO';
                if ((Comparaison = 'KO') or (NbrExtra = 0)) then  // Ajoute l'extra si la comparaison n'est pas bonne ou que le nombre d'extra est égale à 0
                  begin
                    idx := AddExtra; // Crée un extra et stock sa position dans la valeur idx
                    SetExtraField(idx, extraFieldCategory, 'Photos du film'); // Stocke la valeur 'Photos du film' dans le champ catégorie de l'extra
                    SetExtraField(idx, extraFieldURL, AdressePhoto); // Stocke dans le champ URL de l'extra, l'adresse de la photo sur le site pour la comparer ultérieurement et ne télécharger que les photos que l'on n'a pas déjà
                    SetExtraField(idx, extraFieldDescription, CleanText(findInfo('alt="', '"', Value,'0'))); // Stocke la description de la photo donnée par le site dans le champ description de l'extra
                    SetExtraField(idx, extraFieldTitle, TextBefore(AdressePhoto, '.jpg', '/')); // Stocke le nom de la photo sur les serveurs du site dans le champ titre de l'extra
                    GetExtraPicture(idx, AdressePhoto); // Récupère l'image
                    if GetExtraPictureWidth(idx) < 1 then // Evite de récupérer un extra sans image en supprimant l'extra si l'image fait moins de 1 pixel de large
                    DeleteExtraOfScript(idx);
                  end;
                end;
              delete(Value, 1, Pos('src=', Value)+4);
              BeginPos := Pos(UTF8Encode('data-src="'), Value);
              until (BeginPos = 0);
              end;
  end;

///------------------------------------------------------------------------------
// IMPORTE LES PHOTOS DES ACTEURS COMME EXTRAS              Ajouté 2.08 R_V
//------------------------------------------------------------------------------

procedure Extra_Photos_Acteurs(Value : String);
Var
  AdressePhoto, Acteur, Role, AdresseExtra, Comparaison : String;
  idx, NbrExtra, i : Integer;

          begin
		      if pos('<img class="thumbnail-img"', Value) > 0 then   // vérifie que la photo de l'acteur existe
		        begin
              AdressePhoto := TextBetween(Value, 'data-src="', '"');
              Acteur :=  TextBetween(Value, '<span itemprop="name">', '</span>');
              Role := TextBetween(Value, UTF8Encode('Rôle : '), '</div>');
              if (AdressePhoto <> '') and (Pos('empty_photo.jpg', AdressePhoto) = 0) and (Pos('empty_star.jpg', AdressePhoto) = 0) then
            begin
              AdressePhoto := StringReplace(AdressePhoto, '/c_160_213', '');
              AdressePhoto := StringReplace(AdressePhoto, '.JPG', '.jpg');
              NbrExtra := GetExtraCount;
              For i := 0 to NbrExtra-1 do  //  Début boucle pour comparer les adresses des images déja dans la base avec celles du site
              if GetExtraField(i, eCategory) = 'Acteurs et Actrices' then  // ne compare que les extras ayant pour catégorie : 'Acteurs et Actrices'
                begin
                  AdresseExtra := GetExtraField(i , extraFieldURL);
                  if (AdresseExtra = AdressePhoto) then
                    begin
                    Comparaison := 'OK';
                    Break;
                    end else
                    begin
                    Comparaison := 'KO';
                    end;                  // fin boucle comparaison
                end else
                Comparaison := 'KO';
              if ((Comparaison = 'KO') or (NbrExtra = 0)) then  // Ajoute l'extra si la comparaison n'est pas bonne ou que le nombre d'extra est égale à 0
                begin
                  idx := AddExtra;
                  SetExtraField(idx, extraFieldCategory, 'Acteurs et Actrices');
                  SetExtraField(idx, extraFieldURL, AdressePhoto);
                  SetExtraField(idx, extraFieldDescription, CleanText(Role));
                  SetExtraField(idx, extraFieldTitle, CleanText(Acteur));
                  GetExtraPicture(idx, AdressePhoto);
                  if GetExtraPictureWidth(idx) < 1 then // Evite de récupérer un extra sans image en supprimant l'extra si l'image fait moins de 1 pixel de large
                  DeleteExtraOfScript(idx);
                end;
            end;
	         end;
          end;
          
//------------------------------------------------------------------------------
// ANALYSE DE LA PAGE SECRETS DE TOURNAGE  Ajouté 2.09 R_V
//------------------------------------------------------------------------------

procedure SecretComplet(pageSecret: string);
var
  Line, Titre, Texte, La_liste :string;
begin
//charge la page
  if GetOption('ABlock') = 1 then
  begin
    Launch(pageSecret, '');
    Sleep(StrToInt(GetParam('Pause'), 0));
  end;
  Line := GetPage(pageSecret);
  if Pos('<span class="title-punchline">', Line) > 0 then
  begin
//liste des secrets
  Line := TextBetween(Line, '<span class="title-punchline">' , '</section>');
  delete(Line, 1, Pos('<div class="trivia hred">', Line));
    while Pos('<div class="trivia-news">', Line) > 0 do
    begin
     // titre
     Titre := CleanText(TextBetween(Line, '<h2 class="trivia-title">', '</h2>'))+#13#10;
     // secret
     Texte := CleanText(TextBetween(Line, '<div class="trivia-news">', '</div>'))+#13#10#13#10;
     // liste
     La_liste := La_liste+Titre+Texte;
     delete(Line, 1, Pos('<div class="trivia-news">', Line));
    end;
  La_liste := deleteEnd(La_liste, #13#10);
  if GetField(fieldComments) <> '' then
  SetField(fieldComments, GetField(fieldComments)+#13#10#13#10+'Secrets de tournage :'+#13#10#13#10+La_liste)
  else
  SetField(fieldComments, 'Secrets de tournage :'+#13#10#13#10+La_liste);
  end;
end;

//------------------------------------------------------------------------------
// ANALYSE DE L' EQUIPE TECHNIQUE  Ajouté 2.15 R_V
//------------------------------------------------------------------------------

procedure EquipeTechnique(AdresseCasting: string);
var
  Value, Page, Metier, Nom, Liste :string;
begin
  if GetOption('ABlock') = 1 then
  begin
    Launch(AdresseCasting, '');
    Sleep(StrToInt(GetParam('Pause'), 0));
  end;
  Page := GetPage(AdresseCasting);
  Page := TextBetween(Page, '>Equipe technique</h2></div>' , '<div class="section casting-list">');
  while Pos('</div>', Page) > 0 do
  begin
    Value := TextBetween(Page, '<div class="row md-table-row ">' , '</div>');
    Metier := TextBetween(Value, '<span class="col-xs-12 col-sm-6 item">' , '</span>');
    Nom := TextBetween(Value, 'title="' , '"');
    Liste := Liste + '.' + #13#10 + '- '+ Metier + ' : ' + Nom;
    delete(Page, 1, Pos('</div>', Page));
    if GetOption('Equipe technique') = 2 then
    begin
      while Pos(Metier, Page) > 0 do
      begin
        Value := TextBetween(Page, '<div class="row md-table-row ">' , '</div>');
        Nom := TextBetween(Value, 'title="' , '"');
        Liste := Liste + ', ' + Nom;
        delete(Page, 1, Pos('</div>', Page));
      end;
    end;
  end;
  Liste := deleteEnd(Liste, '-  : ');
  Liste := 'Equipe Technique :'+UTF8Decode(Liste);
  HtmlDecode(Liste);
  Liste := StringReplace(Liste, ':.', ':');
  Liste := deleteEnd(Liste, #13#10);
  if GetField(fieldComments) <> '' then
  SetField(fieldComments, GetField(fieldComments)+#13#10#13#10+Liste)
  else
  SetField(fieldComments, Liste);
end;

//------------------------------------------------------------------------------
// ANALYSE DE LA PAGE BANDE ANNONCE  Ajouté 2.20 R_V
//------------------------------------------------------------------------------

procedure BandeAnnonce(pageBA: string);
var
  Value, Page :string;
begin
  if GetOption('ABlock') = 1 then
  begin
   Launch(pageBA, '');
   Sleep(StrToInt(GetParam('Pause'), 0));
  end;
  Page := GetPage(pageBA);
  Value := TextAfter(Page, 'Bandes-annonces & Teasers');
  Value := TextBetween(Page, '/video/player_gen_cmedia=', '&');
  if Value <> '' then
  begin
    Value := 'Bande Annonce : ' + urlAllocine + '/_video/iblogvision.aspx?cmedia=' + CleanText(Value);
    if GetField(fieldComments) <> '' then
    SetField(fieldComments, GetField(fieldComments)+#13#10#13#10+Value)
    else
    SetField(fieldComments,Value);
  end;
end;

//------------------------------------------------------------------------------
// ANALYSE DE LA PAGE DE RECHERCHES
//------------------------------------------------------------------------------
procedure AnalyzePage(Address: string);
var
  Line: string;
  BeginPos, EndPos : Integer;
begin
  if GetOption('ABlock') = 1 then
  begin
    Launch(Address, '');
    Sleep(StrToInt(GetParam('Pause'), 0));
  end;
  Line := GetPage(Address);
  if pos(UTF8Encode('arrive pas à trouver de résultats pour votre recherche'), Line) <> 0 then
  begin
    ShowMessage('Aucun résultat trouvé');
    Exit;
  end;
  if pos(UTF8Encode('1 résultat trouvé'), Line) > 0 then
  begin
    Address := TextBetween(Line, '<td style=" vertical-align:top;">', '</td>');
    Address := urlAllocine + TextBetween(Address, '<a href=''', '''');
    AnalyzeMoviePage(Address);
  end else
  begin
    PickTreeClear;
    AddMoviesTitles(TextBetween(Line, UTF8Encode('Merci de préciser votre recherche :'), '<div class="searchenginezone">'));
    if PickTreeExec(Address) then
    begin
      AnalyzeMoviePage(Address);
    end;
  end;
end;

procedure AddMoviesTitles(Results: string);
var
  Block, Title, Address, Year, Director: string;
begin
  if getfield(fieldYear) <> '' then
  PickTreeAdd(CleanText(TextBefore(Results, '</div>', ''))+' ['+MovieName+' ('+getfield(fieldYear)+')]', '')
  else
  PickTreeAdd(CleanText(TextBefore(Results, '</div>', '')), '');
  while Pos('tr><td style=" vertical-align:top;">', Results) > 0 do
  begin
    Block := TextBetween(Results, 'tr><td style=" vertical-align:top;">', '</tr>');
    Results := RemainingText;
    Address := urlAllocine + TextBetween(Block, '<a href=''', '''>');
    Title := TextBefore(Block, '<br />', '');
    Year := TextBetween(Block, '<span class="fs11">', '<br />');
    Director := TextBetween(Block, '<br />'+#13#10+'de ', '<br />');
    PickTreeAdd(CleanText(Title) + ' (' + CleanText(Year) + ')' + ' de ' + CleanText(Director), Address);
  end;
end;

function CleanText(Text: string): string;
begin
  HtmlRemoveTags(Text);
  Text := UTF8Decode(Text);
  HtmlDecode(Text);
  Text := StringReplace(Text, #13#10, ' ');
  Text := Trim(Text);
  while Pos('  ', Text) > 0 do
  begin
    Text := StringReplace(Text, '  ', ' ');
  end;
  Result := Text;
end;

procedure AnalyzeMoviePage(Address: string);
var
  Page, Value, ID: string;
  i: Integer;
begin
  if GetOption('Garder les valeurs du champ Commentaires') = 0 then
  SetField(fieldComments,'');
  SetField(fieldUrl, Address);
  if GetOption('ABlock') = 1 then
  begin
    Launch(Address, '');
    Sleep(StrToInt(GetParam('Pause'), 0));
  end;
  Page := GetPage(Address);
  // adresse
  Address := urlAllocine + TextBetween(Page, 'class="item home icon icon-home current" href="', '"');
  if Pos('/film/fichefilm_gen_cfilm=', Address) = 0  then
  Address := urlAllocine + '/film/fichefilm_gen_cfilm=' + TextBetween(Page, 'allocine://open/movie?code=', '"') + '.html';
  SetField(fieldUrl, Address);
  // ID Ajouté 2.07 R_V
    if pos('/film/fichefilm_gen_cfilm=',Address) <> 0 then
    ID := findInfo('/film/fichefilm_gen_cfilm=', '.html', Address,'0');
  // titres
  // Le-Sphinx 12/01/2020 Ajout du Titre FR et Titre Original
  Value := TextBetween(Page, '<h1 class="item">', '</h1>');
  SetField(fieldOriginalTitle, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  SetField(fieldTranslatedTitle, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  if Pos('<span class="what light"> Titre original </span>', Page) > 0 then
  begin
    SetField(fieldTranslatedTitle, formatTitre(CleanText(Value),GetOption('Format du Titre')));
    Value := TextBetween(Page, '<span class="what light"> Titre original </span>', '</div>');
    SetField(fieldOriginalTitle, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  end
  // année
  Value := TextBetween(Page, UTF8Encode('<span class="what light">Année de production</span>'), '</span>');
  SetField(fieldYear, CleanText(Value));
  // réalisateur
  // Le-Sphinx 12/01/2020 Ajout Nom du Réalisateur
  Value := TextBetween(Page, 'director" content="', '"');
  if Pos('<span class="light">De</span>', Page) > 0 then
  begin
    Value := TextBetween(Page, '<span class="light">De</span>', '</div>');
    SetField(fieldDirector, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  end else
  SetField(fieldDirector, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  // genres
  // Le-Sphinx 12/01/2020 Ajout les Categories
  Value := TextBetween(Page, '<div class="meta-body-item meta-body-info">', '</div>');
  Value := Copy(Value, Pos('<span class="spacer">/</span>', Value)+29, Length(Value) - Pos('<span class="spacer">/</span>', Value)+29);
  Value := Copy(Value, Pos('<span class="spacer">/</span>', Value)+29, Length(Value) - Pos('<span class="spacer">/</span>', Value)+29);
  if Pos('s', Value) = 1 then
    Value := Copy(Value, 2, Length(Value) - 1);
  SetField(fieldCategory, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  // pays
  // Le-Sphinx 12/01/2020 Format du Pays
  Value := TextBetween(Page, UTF8Encode('<span class="light">Nationalité'), '</div>');
  if Pos('s', Value) = 1 then
    Value := Copy(Value, 2, Length(Value) - 1);
  SetField(fieldCountry, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  // résumé
  Value := TextBetween(Page, UTF8Encode('Synopsis et détails</h2>'), '<div class="ovw-synopsis-info">');
  if Value <> '' then
  begin
    if Pos('certificate-text', Value) > 0 then
    begin
      Value := TextBefore(Value, '</span>', '');
      if CheckVersion(4,2,0) then
      begin
        SetField(fieldCertification, CleanText(Value));
      end;
      SetField(fieldDescription, CleanText(RemainingText));
    end
    else
      SetField(fieldDescription, CleanText(Value));
  end;
  // image
  if (CanSetPicture()) and (GetOption('Choix Image') > 0) then
  begin
    Value := TextBetween(Page, '<figure class="thumbnail ">', '</figure>');
    Value := TextBetween(Value, '<img class="thumbnail-img" src="', '"');
    if Value <> '' then
    begin
      if GetOption('Choix Image') = 2 then
        Value := StringReplace(Value, '/c_215_290/', '/');
      GetPicture(Value);
    end;
  end;
  // Extra Picture Ajouté 2.07 R_V
  if (CheckVersion(4,2,0)) and (GetOption('Extra : Photos du film') = 1) then
  begin
    if pos('/film/fichefilm-'+ID+'/photos', Page) > 0 then   // vérifie que la page photos existe
      begin
        if GetOption('ABlock') = 1 then
        begin
          Launch(urlFicheFilm+ID+'/photos/', '');
          Sleep(StrToInt(GetParam('Pause'), 0));
        end;
        Value := GetPage(urlFicheFilm+ID+'/photos/');
        if Pos('Photos</h2>', Value) <> 0 then
          begin
            Value := TextBetween(Value, 'Photos</h2>', '</section>'); // récupère la portion de code contenant les adresses des photos du film
            Value := StringReplace(Value, '/c_300_300', ''); // Nettoie le code pour récupérer les plus grandes images possibles
            Value := StringReplace(Value, '.JPG', '.jpg');
            Extra_Photos_Film(Value);
          end;
      end;
  end;
  // durée
  // Le-Sphinx 12/01/2020 Ajout Heure du Film en minute
  Value := TextBetween(Page, '<div class="meta-body-item meta-body-info">', '</div>');
  Value := TextBetween(Value, '<span class="spacer">/</span>', '<span class="spacer">/</span>');
  i := StrToInt(TextBefore(Value, 'h', ' '), 0) * 60 + StrToInt(TextBetween(Value, 'h ', 'min'), 0);
  SetField(fieldLength, IntToStr(i));
  // Date de sortie Cinéma (champ Commentaires) Ajouté 2.13 R_V
  // Le-Sphinx 12/01/2020 Ajout de la Date de Sortie
  if CanSetField(fieldComments) then
  begin
    Value := TextBetween(Page, '<div class="meta-body-item meta-body-info">', '</div>');
    Value := TextBetween(Value, '<span class="', '<span class="');
    Value := 'Date de sortie cinéma : ' + CleanText(TextBetween(Value, '">', '</strong>'));
    if GetField(fieldComments) <> '' then
    SetField(fieldComments, GetField(fieldComments)+#13#10#13#10+Value)
    else
    SetField(fieldComments,Value);
  end;
  // note
  if CanSetField(fieldRating) or CanSetField(fieldComments) then
  begin
    Value := TextBetween(Page, '<div class="rating-item">', '<section class="section">');
    GetNote(Value);
  end;
  // Bande Annonce (champ Commentaires) Ajouté 2.13 R_V
  if (CanSetField(fieldComments)) and (Pos('toutes/">Bandes-annonces', Page) > 0) then
  BandeAnnonce(urlAllocine+'/videos/fichefilm-'+ID+'/toutes/');
  // Fiche Technique (champ Commentaires) Ajouté 2.16 R_V
  if (CanSetField(fieldComments)) and (GetOption('Fiche technique') > 0) then
  begin
    Value := TextBetween(Page, 'Voir les infos techniques' , '</section>');
    Value := StringReplace(Value, '<span class="that', ' : <span class="that');
    Value := StringReplace(Value, '<span class="what light">', '##- ');
    Value := CleanText(Value);
    Value := StringReplace(Value, '##', #13#10);
    if GetField(fieldComments) <> '' then
    SetField(fieldComments, GetField(fieldComments)+#13#10#13#10+'Fiche Technique :'+Value)
    else
    SetField(fieldComments, 'Fiche Technique :'+Value);
  end;
  // Equipe Technique (champ Commentaires) Ajouté 2.15 R_V
  if (CanSetField(fieldComments)) and (GetOption('Equipe technique') > 0) then
  EquipeTechnique(urlAllocine + '/film/fichefilm-' + ID + '/casting/');
  // Secrets de tournage  Ajouté 2.09 R_V
  if (CanSetField(fieldComments)) and (GetOption('Secrets de tournage') = 1) then
  begin
	 if (pos('Secrets de tournage</span></h2>', Page) <> 0) then
	 begin
		Value := urlAllocine+'/film/fichefilm-'+ID+'/secrets-tournage/';
		SecretComplet(Value);
	 end;
  end;
  // acteurs
  if GetOption('Acteurs') > 1 then
  begin
    GetActors(urlAllocine + '/film/fichefilm-' + ID + '/casting/');
  end
  else
  if GetOption('Acteurs') = 1 then
  begin
    Value := TextBetween(Page, '<span class="light">Avec</span>', '</div>');
    if Pos(' plus </span>', Value) > 0 then
      Value := TextBefore(Value, ' plus </span>', '');
    SetField(fieldActors, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  end;
  // Pour purger la fin des commentaires de retours à la ligne en trop
  Value := GetField(fieldComments);
  repeat
  Value := deleteEnd(Value, #13#10);
  Until (copy(Value,length(Value)-length(#13#10)+1,length(Value)) <> #13#10);
  SetField(fieldComments, Value);
end;

procedure GetActors(Address: string);
var
  Roles: Boolean;
  Page, Section, Block, Value, Actors: string;
begin
  if GetOption('ABlock') = 1 then
  begin
    Launch(Address, '');
    Sleep(StrToInt(GetParam('Pause'), 0));
  end;
  Page := GetPage(Address);
  if CanSetField(fieldActors) then
  begin
    if Pos('>Acteurs et actrices</h2></div>', Page) > 0 then
    begin
      Section := TextAfter(Page, '>Acteurs et actrices</h2></div>');
      Actors := AllActors(Section);
    end;
    if Pos('>Acteurs de doublage (Voix originales)</h2></div>', Page) > 0 then
    begin
      Section := TextAfter(Page, '>Acteurs de doublage (Voix originales)</h2></div>');
      Value := AllActors(Section);
      if Value <> '' then
      begin
        if Actors <> '' then
          Actors := Actors + ', ' + Value
        else
          Actors := Value;
      end;
    end;
    if Pos('>Acteurs de doublage (Voix locales)</h2></div>', Page) > 0 then
    begin
      Section := TextAfter(Page, '>Acteurs de doublage (Voix locales)</h2></div>');
      Value := AllActors(Section);
      if Value <> '' then
      begin
        if Actors <> '' then
          Actors := Actors + ', ' + Value
        else
          Actors := Value;
      end;
    end;
    SetField(fieldActors, Actors);
  end;
  if CanSetField(fieldProducer) then
  begin
    SetField(fieldProducer, GetPoste(Page, 'Producteur</span>'));
  end;
  if CheckVersion(4,2,0) then
  begin
    if CanSetField(fieldComposer) then
    begin
      SetField(fieldComposer, GetPoste(Page, 'Compositeur</span>'));
    end;
    if CanSetField(fieldWriter) then
    begin
      SetField(fieldWriter, GetPoste(Page, UTF8Encode('Scénariste</span>')));
    end;
  end;
end;

function GetPoste(Section: string; PosteTag: string): string;
var
  Block, Value: string;
begin
  Block := '';
  while Pos(PosteTag, Section) > 0 do
  begin
    Value := TextBetween(Section, PosteTag, '</div>');
    Section := RemainingText;
    if Block <> '' then
      Block := Block + ', ';
    Block := Block + CleanText(Value);
  end;
  Result := Block
end;

procedure GetNote(Value: string);
var
  NotePresse, NoteSpectateurs, NoteSur10,RatingCountSpectateurs: string;
begin
  if (Pos('presse',Value)>0) then
  begin
    NotePresse := TextAfter(Value, '<span class="stareval-note"');
    NotePresse := CleanText(TextBetween(NotePresse, '>', '<'));
    NotePresse := StringReplace(NotePresse, '?', '');
    Value := TextAfter(Value, '<span class="stareval-note"');
  end;
  NoteSpectateurs := TextBetween(Value, '<span class="stareval-note"', '/span>');
  NoteSpectateurs := CleanText(TextBetween(NoteSpectateurs, '>', '<'));
  NoteSpectateurs := StringReplace(NoteSpectateurs, '?', '');
  RatingCountSpectateurs := TextBetween(Value, '<span itemprop="ratingCount">', '</span>');
  if (NotePresse <> '') and (NoteSpectateurs <> '') then
  begin
    NoteSur10 := FloatToStr(arrondir(convert_STF(NotePresse),1) + arrondir(convert_STF(NoteSpectateurs),1));
    SetField(fieldRating,NoteSur10);
  end else
  if (NotePresse <> '') then
  begin
    NoteSur10 := FloatToStr(arrondir(convert_STF(NotePresse),1)*2);
    SetField(fieldRating,NoteSur10);
  end else
  if (NoteSpectateurs <> '') then
  begin
    NoteSur10 := FloatToStr(arrondir(convert_STF(NoteSpectateurs),1)*2);
    SetField(fieldRating,NoteSur10);
  end;
  Value := '';
  if NotePresse <> '' then
  Value := 'Note de la presse : '  + NotePresse + '/5';
  if NoteSpectateurs <> '' then
  begin
    if Value <> '' then
    Value := Value + #13#10 + 'Note des spectateurs : ' + NoteSpectateurs + '/5' + ' (Pour ' + RatingCountSpectateurs + ' notes)'
    else
    Value := 'Note des spectateurs : ' + NoteSpectateurs + '/5' + ' (Pour ' + RatingCountSpectateurs + ' notes)';
  end;
  if (Value <> '') and (GetOption('Détail des notes') > 0) then
  begin
    if GetField(fieldComments) <> '' then
    SetField(fieldComments, GetField(fieldComments)+#13#10#13#10+Value)
    else
    SetField(fieldComments,Value);
  end;
end;

begin
  if CheckVersion(3,5,1) then
  begin
    if GetStatic('InfoV2') = '' then
    begin
      ShowMessage('Ce script a été créé "rapidement" afin de fournir une solution de dépanage suite aux gros changements survenus sur le site d''Allociné. Pour le moment il ne supporte que les fiches de films (pas de séries) et n''intègre pas autant d''options que l''ancien script. Il sera amélioré petit à petit.');
      SetStatic('InfoV2', 'ok');
    end;
    MovieName := GetField(fieldUrl);
    if Pos(urlAllocine, MovieName) = 0 then
    begin
      MovieName := recupTitreRecherche(GetOption('Recherche sur le titre'));
    end;
    if ((GetOption('Batch') = 1) and (Pos(urlAllocine, MovieName) > 0)) then
      AnalyzeMoviePage(MovieName)
    else
    begin
      if Input('Allociné', 'Entrez le titre du film ou l''adresse d''une page', MovieName) then
      begin
        if Pos(urlAllocine, MovieName) > 0  then
          AnalyzeMoviePage(MovieName)
        else
        begin
          if CheckVersion(4,2,2) then
            AnalyzePage(urlSearch + UrlEncode(MovieName))
          else
            AnalyzePage(urlSearch + UrlEncode(UTF8Encode(MovieName)));
        end;
      end;
    end;
  end else
    ShowMessage('This script requires a newer version of Ant Movie Catalog (at least the version 3.5.1)');
end.

Posted: **2020-01-12 09:08:56**

Merci, c'est mis à jour (v2.41)... je suppose que ça comporte aussi les modifs de Clement ?

Posted: **2020-01-12 11:14:37**

Bonjour
le réalisateur et la catégorie sont revenus mais pas les acteurs
merci d'avance

Posted: **2020-01-12 13:30:05**

antp wrote: ↑2020-01-12 09:08:56 Merci, c'est mis à jour (v2.41)... je suppose que ça comporte aussi les modifs de Clement ?

Clement avait modifié le script, puis est revenu en arrière. mais oui c'est à jour avec.

chob wrote: ↑2020-01-12 11:14:37 Bonjour
le réalisateur et la catégorie sont revenus mais pas les acteurs
merci d'avance

Les acteurs fonctionne de mon coté pourtant, quel film pose problème ?

Posted: **2020-01-12 14:05:07**

Super Le-Sphinx,
Merci pour la version 2.41 du script.
Elle fonctionne très bien, y compris la catégorie et les acteurs.

Encore merci pour ton aide.

Posted: **2020-01-12 14:07:54**

Bonjour,
Je viens d'en tester plusieurs, et effectivement, il manque les acteurs (option Acteurs=1 pour ne prendre que ceux de la page principale) :
- Les Aventures de Rocketeer
- Crazy kung-fu
par exemple...
En fait, ça ne semble fonctionner que si l'on active l'option Roles Acteurs = 1 et que l'on place l'option Acteurs = 2

FB

Posted: **2020-01-12 15:21:58**

en effet ça marche nickel en faisant les modifs

Posted: **2020-01-12 15:47:31**

Chez moi c'est Acteurs = 3 et rôle acteurs = 0 et il n'y a pas de problème

Posted: **2020-01-12 22:48:21**

boyerf wrote: ↑2020-01-12 14:07:54 Bonjour,
Je viens d'en tester plusieurs, et effectivement, il manque les acteurs (option Acteurs=1 pour ne prendre que ceux de la page principale) :
- Les Aventures de Rocketeer
- Crazy kung-fu
par exemple...
En fait, ça ne semble fonctionner que si l'on active l'option Roles Acteurs = 1 et que l'on place l'option Acteurs = 2

FB

Code a remplacer dans l'editeur de la ligne 576 à 589 :

Code: Select all

  // acteurs
  if GetOption('Acteurs') > 1 then
  begin
    GetActors(urlAllocine + '/film/fichefilm-' + ID + '/casting/');
  end
  else
  // Le-Sphinx 12/01/2020 Ajout Acteur
  if Pos('<span class="ligth">Avec</span>', Page) > 0 then
  begin
    Value := TextBetween(Page, '<span class="ligth">Avec</span>', '</div>');
    SetField(fieldActors, formatTitre(CleanText(Value),GetOption('Format du Titre')));
  end else
  // Pour purger la fin des commentaires de retours à la ligne en trop

Posted: **2020-01-17 09:51:05**

Merci, mais c'est voulu ce "else" à la fin ?
Ça rend conditionnelle la ligne (non visible ici) qui suit le commentaire donc

Posted: **2020-01-18 17:31:40**

antp wrote: ↑2020-01-17 09:51:05 Merci, mais c'est voulu ce "else" à la fin ?
Ça rend conditionnelle la ligne (non visible ici) qui suit le commentaire donc

ha non, j'avais programmé une autre façon avant plus complexe et plus longue, il vient de la le else ^^

Posted: **2020-01-19 09:17:08**

Peut-être me renvoyer la version complète du script pour être sûr ?

(e-mail ou https://ks3c.antp.be/upload.php)

Posted: **2020-03-12 16:01:58**

Bonjour,
le script ne semble plus marcher aujourd'hui, erreur 404.

Posted: **2020-03-13 09:22:01**

Bonjour,
Je confirme le script ne fonctionne plus

Posted: **2020-03-13 17:41:13**

Bonjour
je confirme également que le script ne fonctionne plus.
Merci aux gourous de nous aider et le faire fonctionner.

Posted: **2020-03-13 17:43:41**

Bonjour,
J'ai jeté un oeil et tout d'abord il faut modifier l'adresse de recherche dans le script (remplacer "/recherche/1/?q=" par "/recherche/movie/?q=")
Ensuite je n'ai pas trouvé comment récupérer l'adresse de la fiche depuis la page de résultat, je ne la vois pas clairement dans le code (il doit y avoir une astuce).
Pour dépanner je rappelle qu'on peut rentrer l'adresse de la fiche à la place du titre pour qu'il aille directement chercher les données sans passer par la phase de recherche, il faut juste faire la recherche soi même sur le site et récupérer le lien.

Posted: **2020-03-13 20:38:44**

En effet le lien ne semble plus dans le code (ni même l'identifiant du film permettant de construire le lien).
Je suppose que ce lien est reconstruit par javascript ensuite, à partir d'infos plus ou moins cachées.
Peut-être pour éviter qu'on puisse faire une recherche sans passer par le site... ça ne sera peut-être pas simple à contourner

Posted: **2020-03-17 17:52:48**

Bonsoir,
Y-a-t-il un espoir que quelqu’un résolve ce problème?

Allociné est à ma connaissance le seul site avec script qui contient la majorité des champs pour remplir ANT ?

Posted: **2020-03-17 19:03:00**

Pour l'instant la solution est de copier/coller directement l'adresse de la fiche Allociné lorsqu'on utilise le script Allociné, ça fonctionne bien pour l'instant

Posted: **2020-03-22 10:43:51**

Bonjour la compagnie,
Je me suis penché sur ce problème (qui semble intéresser beaucoup de monde) et j'ai trouvé une solution alternative pour la recherche. C'est pourtant simple, qui dit recherche sur internet dit Google. J'utilise donc le moteur de recherche Google pour chercher les films. Pour ceux qui ne le savent pas on peut faire de la recherche Google sur un site en particulier en rajoutant à sa recherche le site sous le format suivant : "site:allocine.fr". La recherche étant globale à la page on peut trouver des résultats plus ou moins correspondant à ce qu'on cherche, il faut donc faire un peu d'adaptation. J'ai donc fait une version qui marche pas trop mal sur les tests que j'ai fait, elle est dispo ici : Allocine (FR).ifs. J'ai rajouté une option au script pour sélectionner la recherche Google, en attendant que quelqu'un trouve une façon de faire marcher la recherche du site.

antp.be forum

[REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2

Re: [REL] [FR] Allociné v2