FilmAffinity (ES): New version of the script

[aviloria]

Os dejo la nueva versión del script FilmAffinity (ES) adaptada a los cambios en la página.
No dudéis en avisarme si encontráis algún problema con el script.

Disfrutadla!

Edit: De ahora en adelante actualizaré el código del script siempre en esta entrada. De esta forma espero que sea más claro para todos.

----

The new version of the FilmAffinity (ES) script, complaining with recent web changes, is attached below.
Please, let me know if you found any unexpected issue using the script.

Enjoy!

Edit: Now on, I will update the script code always in this post entry. I hope it will be clearest for everybody.

_____________________________________________


Script Versión : v2.65 (2013-04-25)

Code: Select all

(***************************************************

Ant Movie Catalog importation script
www.antp.be/software/moviecatalog/

[Infos]
Authors=aviloria (aviloria@yahoo.com) modded by: rodpedja (rodpedja@gmail.com), kreti (bisoft@hotmail.com), MrK, gilistico, juliojs
Title=FilmAffinity (ES)
Description=Movie importation script for FilmAffinity Spain
Site=http://www.filmaffinity.com
Language=ES
Version=2.65
Requires=3.5.0
Comments=Updated to 2013/04/16 version of the web-page. Added an option to choose Actor list format (ActorsInALine).
License=The source code of the script can be used in another program only if full credits to script author and a link to Ant Movie Catalog website are given in the About box or in the documentation of the program.|
GetInfo=1
RequiresMovies=1

[Options]
DontAsk=0|0|1=Método rápido: No te pregunta el titulo al principio, ni te pide confirmar si sólo hay un resultado|0=Método lento: Confirmas la información manualmente
ActorsInALine=0|0|1=Actores separados por comas|0=Actores en lineas independientes

[Parameters]

***************************************************)

program FilmAffinity;
const
   BaseURL = 'http://www.filmaffinity.com';
var
   MovieName: string;
   MovieURL: string;
   
//------------------------------------------------------------------------------------

function FindLine(Pattern: string; List: TStringList; StartAt: Integer): Integer;
var
   i: Integer;
begin
   Result := -1;
   if StartAt < 0 then StartAt := 0;
   for i := StartAt to List.Count-1 do
      if Pos(Pattern, List.GetString(i)) <> 0 then
      begin
         Result := i;
         Break;
      end;
end;

//------------------------------------------------------------------------------------

function TextBetween(S: string; StartTag: string; EndTag: string): string;
var
   ini, fin: Integer;
begin
   Result := '';
   ini := Pos(StartTag, S);
   if ini <> 0 then
   begin
      ini := ini + Length(StartTag);
      fin := Pos(EndTag, S);
      if (fin <> 0) and (fin > ini) then
      begin
         Result := Copy(S, ini, fin - ini);
      end;
   end;
end;

//------------------------------------------------------------------------------------

function DeleteTags(S: string): string;
var
   n, len, tag: Integer;
   c, p: char;
begin
   HTMLDecode(S);
   len    := Length(S);
   tag    := 0;
   p      := ' ';
   Result := '';
   for n := 1 to len do
   begin
      c := Copy(S,n,1);

      // Eliminamos los tabuladores
      if c = #9 then c := ' ';

      // Los espacios redundantes no se procesan
      if (c <> ' ') or (p <> ' ') then
      begin
         // Eliminamos los tags de HTML
         if tag = 0 then
         begin
            if c <> '<' then
            begin
               Result := Result + c;
               p := c;
            end
            else tag := 1;
         end
         else if c = '>' then tag := 0;
      end;
   end
   if p = ' ' then Result := Copy(Result, 1, Length(Result) - 1);
end;

//------------------------------------------------------------------------------------

procedure AnalyzePage(Address: string);
var
   Page: TStringList;
   LineNr: Integer;
   Line: string;
   Count: Integer;
   MovieTitle, MovieAddress: string;

begin
   Count := 0;
   Page  := TStringList.Create;
   Page.Text := GetPage(Address);
   PickTreeClear;

   // Get how much search results have been found
   LineNr := FindLine('</strong> resultados.</div>', Page, 0);
   if LineNr <> -1 then
   begin
      Line  := Page.GetString(LineNr);
      Count := StrToInt(TextBetween(Line, '<div style="text-align:right;"><strong>', '</strong> resultados.</div>'), 0);
   end;

   // Add the results to the PickTree
   if Count = 0 then
      ShowMessage('No se ha encontrado ningún registro')
   else
   begin
      LineNr := 0;
      while true do
      begin
         LineNr := FindLine('<div class="mc-title"><a href="', Page, LineNr + 1);
         if LineNr = -1 then
         begin
            LineNr := FindLine('<b>siguientes >></b>', Page, 0);
            if LineNr = -1 then
               break;
            Line      := Page.GetString(LineNr);
            Page.Text := GetPage(TextBetween(Line, '<a href="', '">'));
            LineNr    := 0;
            continue;
         end;

         Line         := Page.GetString(LineNr);
         MovieAddress := TextBetween(Line, '<div class="mc-title"><a href="', '.html">') + '.html';
         
         MovieTitle   := DeleteTags(TextBetween(Line, '.html">', '<img src="'));

         if (Length(MovieAddress) <> 0) and (Length(MovieTitle) <> 0) then
            PickTreeAdd(MovieTitle, BaseURL + MovieAddress);
      end;

      if ((Count = 1) and (GetOption('DontAsk') = 1)) or PickTreeExec(Address) then
         AnalyzeMoviePage(Address);
   end;
   Page.Free;
end;

//------------------------------------------------------------------------------------

procedure AnalyzeMoviePage(Address: string);
var
   Page: TStringList;
   LineNr, LineInc: Integer;
   Line: string;
   Item: string;
   Comments: string;

begin
   Comments := '';

   // URL
   SetField(fieldURL, Address);

   Page := TStringList.Create;
   Page.Text := GetPage(Address);

   // Translated Title
   LineNr := FindLine('<h1 id="main-title">', Page, 0);
   Line := Page.GetString(LineNr);
   Item := DeleteTags(TextBetween(Line, '<h1 id="main-title">', '</h1>'));
   SetField(fieldTranslatedTitle, Item);

   // Picture
   LineNr := FindLine('http://pics.filmaffinity.com/', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr);
      Item := TextBetween(Line, '<a class="lightbox" href="', '" title="');
      if Length(Item) = 0 then
         Item := TextBetween(Line, '" src="', '"></a>');
      GetPicture(Item);
   end;

   // Rating
   LineNr := FindLine('<div id="movie-rat-avg">', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(Line);
      SetField(fieldRating, StringReplace(Item, ',', '.'));
   end;

   // Original Title
   LineNr := FindLine('<dt>Título original</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>'));
      SetField(fieldOriginalTitle, Item);
   end;

   // Year
   LineNr := FindLine('<dt>Año</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>'));
      SetField(fieldYear, Item);
   end;

   // Length
   LineNr := FindLine('<dt>Duración</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(TextBetween(Line, '<dd>', 'min.</dd>'));
      SetField(fieldLength, Item);
   end;

   // Country
   LineNr := FindLine('<dt>País</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(TextBetween(Line, 'title="', '" border'));
      SetField(fieldCountry, Item);
   end;
 
   // Director
   LineNr := FindLine('<dt>Director</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>'));
      SetField(fieldDirector, Item);
   end;

   // Script writer
   LineNr := FindLine('<dt>Guión</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := TextBetween(Line, '<dd>', '</dd>');
      Comments := Comments + 'Guión: ' + Item + #13#10 + #13#10;
   end;

   // Composer
   LineNr := FindLine('<dt>Música</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := TextBetween(Line, '<dd>', '</dd>');
      Comments := Comments + 'Música: ' + Item + #13#10 + #13#10;
   end;

   // Photography
   LineNr := FindLine('<dt>Fotografía</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := TextBetween(Line, '<dd>', '</dd>');
      Comments := Comments + 'Fotografía: ' + Item + #13#10 + #13#10;
   end;

   // Actors
   LineNr := FindLine('<dt>Reparto</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>'));
      if GetOption('ActorsInALine') = 0 then Item := StringReplace(Item, ', ', #13#10);
      SetField(fieldActors, Item);
   end;

   // Productor
   LineNr := FindLine('<dt>Productora</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(TextBetween(Line, '<dd>', '</dd>'));
      SetField(fieldProducer, Item);
   end;

   // Category
   LineNr := FindLine('<dt>Género</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 2);
      Item := DeleteTags(Line);
      Item := StringReplace(Item, ' | ', ', ');
      Item := StringReplace(Item, '. ', ', ');
      SetField(fieldCategory, Item);
   end;

   // Official Webpage
   LineNr := FindLine('<dt>Web Oficial</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(TextBetween(Line, ' href="', '">'));
      Comments := Comments + 'Web oficial: ' + Item + #13#10 + #13#10;
   end;

   // Synopsis
   LineNr := FindLine('<dt>Sinopsis</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Line := Page.GetString(LineNr + 1);
      Item := DeleteTags(Line);
      SetField(fieldDescription, Item);
   end;

   // Awards
   LineNr := FindLine('<dt>Premios</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      LineNr   := LineNr + 1;
      Line     := Page.GetString(LineNr);
      Comments := Comments + 'Premios: ' + #13#10;
      while Pos ('</dd>', Line) = 0 do
      begin
         if Pos ('<span id="show-all-awards">', Line) = 0 then
         begin
            Item := DeleteTags(Line);
            if (Length(Item) <> 0) then
            begin
               Comments := Comments + '  - ' + Item + #13#10;
            end;
         end;
         LineNr := LineNr + 1;
         Line   := Page.GetString(LineNr);
      end;
      Comments := Comments + #13#10;
   end;

   // Critic
   LineNr := FindLine('<dt>Críticas</dt>', Page, LineNr);
   if LineNr <> -1 then
   begin
      Comments := Comments + 'Críticas: ' + #13#10 + #13#10;
      LineNr   := FindLine('<div class="pro-review">', Page, LineNr + 1);
      while LineNr <> -1 do
      begin
         LineNr  := LineNr + 1;
         Line    := Page.GetString(LineNr);
         LineInc := 2;
         if Pos ('<a title="Leer crítica completa" href=', Line) <> 0 then
         begin
           LineNr  := LineNr + 1;
           Line    := Page.GetString(LineNr);
           LineInc := 3;
         end;
         Item := DeleteTags(Line);
         if (Length(Item) <> 0) then
         begin
            Comments := Comments + Item + #13#10;
            LineNr := LineNr + LineInc;
            Line := Page.GetString(LineNr);
            Item := DeleteTags(Line);
            if (Length(Item) <> 0) then
            begin
               Comments := Comments + Item + #13#10;
            end;
            Comments := Comments + '________________________________________' + #13#10 + #13#10;
         end;
         LineNr := FindLine('<div class="pro-review">', Page, LineNr + 1);
      end;
   end;

   HTMLDecode(Comments);
   SetField(fieldComments, Comments);
end;

//------------------------------------------------------------------------------------

begin
   if (CheckVersion(3,5,0) = false) then
   begin
      ShowMessage('Se requiere Ant Movie Catalog versión 3.5 o superior');
      exit;
   end;

   MovieName := GetField(fieldOriginalTitle);
   if Length(MovieName) = 0 then
      MovieName := GetField(fieldTranslatedTitle);

   if GetOption('DontAsk') = 0 then
      Input('FilmAffinity', 'Pelicula:', MovieName);

   if Pos('filmaffinity.com', MovieName) > 0 then
      AnalyzeMoviePage(MovieName)
   else
      AnalyzePage(BaseURL +'/es/search.php?stext=' + UrlEncode(MovieName) + '&stype=Title');
end. 

Lista de cambios desde la versión v2.60:

[Added] Se ha añadido una opción (ActorsInALine) en el script para elegir el formato de la lista de actores: en una línea separados por comas; o bien cada uno en una línea independiente (formato columna). Gracias a granguash y jacqlittle por hacerme ver "otras posibilidades".
[Updated] En ocasiones no se obtiene correctamente la duración de la película.
[Fixed] En ocasiones no se obtiene correctamente la sinopsis de la película. Gracias a J.M.Talegón por detectar el fallo.
[Changed] Se ha optimizado el proceso de adquisición de resultados. Gracias a Arturo por hacerme ver ese fragmento de código tan obsoleto.
[Updated] En la página de FilmAffinity han vuelto a modificar el código de la duración de la película. He actualizado el script para adaptarse a los nuevos cambios.
[Fixed] Se ha corregido el caso en el que hay más de 10 críticas y éstas quedan ocultas en la página de FilmAffinity (antes no se importaban). Gracias a m2s por percatarse de ello.
[Changed] He modificado el formato del campo 'Género' para que tenga el formato "Genero1, Genero2, ..., GeneroN"... en vez del que tiene la página. Con esto se mejora la búsqueda por Género en la aplicación. Gracias fotja por la recomendación.
[Updated] He actualizado el script a los últimos cambios de la página. Vuelve a adquirirse correctamente los campos "Género", "Premios", "WebOficial" y "Crítica".

[Fixed] juliojs ha actualizado el script para adaptarlos a los nuevos cambios en la web de FilmAffinity. Gracias juliojs!


----

Change log from release v2.60:

[Added] Added a script option (ActorsInALine) to choose the Actor's list format: all of them in the same line separated by commas; or each one of them in a different line (column format). Thanks to granguash and jacqlittle to let me know other "points of view".
[Updated] Sometimes 'Length' field was empty.
[Fixed] Sometimes 'Synopsis' field was empty. Thanks to J.M.Talegón for debbuging.
[Changed] Web-search result code was optimized. Thanks to Arturo to let me see that obsolete part of code.
[Updated] FilmAffinity website team updated again the web-code, making the script unable to load the 'Length' field. I have updated it to complain the web changes.
[Fixed] When a film has more than 10 critics, the script was unable to load the following critics (hidden in the web-page by default). Thanks to m2s to report this bug.
[Changed] I have changed the format of the 'Category' field to "Cat1, Cat2, ..., CatN"... instead of the original format from the web-page. Now, it's easier to seach by Category in the app. Thanks to fotja to report this issue.
[Updated] Another script update to complain with website changes. It fixes the acquisition of the folowing fields: "Catefory", "Awards", "OfficialWebsite" and "Critic".

[Fixed] juliojs has updated the script to comply with recent changes made in the FilmAffinity web page. Thanks juliojs!

[antp]

Thanks!

[buitre225]

Muchas gracias, estaba perdido sin poder usarlo

[granguash]

Muchísimas gracias por el aporte. Y me da un poco de corte pedir esto, después del curro que habrá supuesto esto, pero habría alguna manera de poder ver el reparto en columna, en lugar de separado por comas.

Muchas gracias de nuevo!!

[jacqlittle]

Me uno a la petición del compañero granguash ya que hasta ahora es así como se importaban los datos, para poder tener toda la base de datos con el mismo formato.

Por supuesto, sólo si se puede y no es mucha molestia, que eso supondrá un currazo impresionante, y por lo cual te agradezco de todo corazón el esfuerzo y que lo compartas con nosotros.

Muchas gracias y un saludo cordial.

[aviloria]

Para poner los nombres de los actores en columnas, tan solo hay que añadir una línea en la sección Actors (ver más abajo).

He aprovechado para corregir un pequeño error según el cual en ocasiones no se toma bien el valor de la 'Duración' de la película (parece que todavía siguen haciendo cambios en la página).

Edit: He reflejado los cambios en el post original

----

To get the actor's list in 'one-per-line' format (old style), you have to add a single line in the Actors section of the script (see below).

Also I have fixed a small bug that prevents a bad value in the 'Length' field (it seems that they're still changing the web).

Edit: I have updated the script code in the original post

[Arturo]

Creo que el siguiente codigo no es necesario:

// Veamos si solo hay un solo resultado
LineNr := FindLine('<strong>1</strong> resultados.', Page, 0);
if LineNr <> -1 then
begin
Line := Page.GetString(LineNr + 11);
Line2 := Line;
MovieAddress := TextBetween(Line, '<a class="mc-title" href="', '">');
MovieTitle := DeleteTags(TextBetween(Line2, '.html">', '</td>'));

if (Length(MovieAddress) <> 0) and (Length(MovieTitle) <> 0) then
begin
MovieAddress := BaseURL1 + MovieAddress;
PickTreeAdd(MovieTitle, MovieAddress);
if (GetOption('DontAsk') = 1) or PickTreeExec(MovieAddress) then
AnalyzeMoviePage(MovieAddress);
end
Page.Free;
exit;
end;


Cuando solo hay un resultado no veo que aparezca la cadena:
<strong>1</strong> resultados

[aviloria]

Nueva versión del script:

[Fixed] En ocasiones no se obtiene correctamente la sinopsis de la película. Gracias a J.M.Talegón por detectar el fallo.
[Changed] Se ha optimizado el proceso de adquisición de resultados. Gracias a Arturo por hacerme ver ese fragmento de código tan obsoleto.

No dudéis en avisarme si encontráis algún problema con el script.

Edit: He reflejado los cambios en el post original

----

New script version:

[Fixed] Sometimes 'Synopsis' field was empty. Thanks to J.M.Talegón for debbuging.
[Changed] Web-search result code was optimized. Thanks to Arturo for let me see that obsolete part of code.

Please, let me know if you found any unexpected issue using the script.

Edit: I have updated the script code in the original post

[Arturo]

Personalmente creo que está mejor así.

De todas formas debo reconocer que yo estaba equivocado. El problema cuando solo hay una pelicula estaba en la línea:

MovieTitle := DeleteTags(TextBetween(Line, '.html">', '</td>'));

Si esta se cambia por:

MovieTitle := DeleteTags(TextBetween(Line2, '.html">', '<imb src='));

funciona.

El conservar esto solo permitiria que en el caso de una sola coincidencia se cargaran los campos sin seleccion previa (DontAsk). Pero personalmente prefiero siempre comprobarlo.

Buen Trabajo aviloria

[aviloria]

Arturo: Con los nuevos cambios también se sigue dando soporte a la opción 'DontAsk', solo que ahora (con la nueva versión de la página web de FilmAffinity) no se necesita tener un caso separado para cuando sólo hay 1 resultado.

Hay que reconocer que aunque yo hice la primera versión del Script, no he podido mantenerlo siempre al día, y otras personas han colaborado en su mantenimiento (cosa que les agradezco profundamente)... pero con el tiempo ésto ha generado fragmentos de código poco claros o que se han quedado obsoletos porque "funcionaban y nadie los quería tocar".

En esta ocasión, creo haber reescrito la mayor parte del código, simplificándolo y optimizándolo un poco.

Un saludo.

[m2s]

Hay un problema al importar las críticas de la película: Si son muchas no importa las últimas (precisamente las de prensa española).
Lo puedes ver por ejemplo en la película "Stand Up Guys" http://www.filmaffinity.com/es/film655898.html
En la página de filmaffinity no se muestran todas, hay un botón para mostrar más, que son las que no se importan.
Por otro lado, sigue sin importarse la duración.
Muchas gracias y felicidades por un trabajo buenísimo.

[fotja]

Agradecer el scrip, yo el error que veo es que a la hora de importar la categoria de la peli como por ejemplo la de LA REINA DE LOS CONDENADOS http://www.filmaffinity.com/es/film914035.html en lugar de poner en la categoria "Terror, Fantástico, Vampiros, Secuela, Musica" me importa el siguiente formato "Terror. Fantástico | Vampiros. Secuela. Música" y a la hora de hacer un reagrupamiento por categorias se monta el lio, si se pudiera arreglar seria perfecto. Gracias de nuevo por el trabajo del Scripts

[granguash]

Perdonadme la torpeza, pero uno que en programación es nulo, no sé cómo tengo que hacer para que aparezcan los actores en columnas. Y por otro lado, con la nueva versión, también me ha fallado la duración de la película que he probado (Bloody Sunday).

Si es cosa mía, y a los demás os va bien, perdonad el lío.

Muchas gracias a todos por vuestra yuda y vuestro trabajo!

[aviloria]

@m2s, @granguash: La gente de FilmAffinity sigue haciendo cambios en la página y por eso dejó de adquirirse bien el campo 'Duración'. Ya he adaptado el script a los nuevos cambio y lo he actualizado en el post inicial.

@m2s: Ya he corregido el caso en el que hay más de 10 críticas en una película y a partir de las 10 primeras aparecen ocultas en la página web de FilmAffinity (y el script no las adquirían bien). Gracias informar de este error.

@fotja: Me ha gustado tu idea para el formato del campo 'Género' de la película. Antes símplemente se dejaba el formato que fijaba FilmAffinity. Ahora los géneros se enumeran separados por comas.
Si alguien tiene algún problema con ésto se puede añadir una opción al script para que el usuario elija el formato de este campo.

@granguash: Las opciones del script se pueden cambiar en la pantalla de selección y ejecución del script. No hace falta modificar el código fuente.

[visent]

Hola!!

Excelente trabajo arreglando el script para que podamos disfrutar de él.

Un par de cuestiones, ¿cómo hago para que se me actualice la info del script? Es decir, versión y tal. Yo lo que he hecho ha sido copiar el código del principio y pegarlo en el lugar que estaba el anterior, pero esa info no se actualiza, y aparentemente, las opciones que dices que podemos seleccionar, no puedo hacerlo.

Y la otra, ¿las carátulas no se podrían extraer de un sitio en castellano?

Gracias por vuestra ayuda y ante todo, gran trabajo!!!

[aviloria]

@visent La mejor forma de actualizar el script es la siguiente:
1) Vas a la carpeta donde tengas instalado el Ant Movie Catalog, y entras en la carpeta "Scripts" (Ej: "C:\Archivos de programa (x86)\Ant Movie Catalog\Scripts")
2) Busca el fichero "FilmAffinity (ES).ifs" y ábrelo con el Bloc de notas (o cualquier otro editor de texto)
3) Borra todo el contenido del fichero y pega el código que encontrarás en la primera entrada de este post.

Cuando arranques la aplicación, añade una nueva película (o selecciona una que ya tengas añadida) y pulsa F6 (o haz Click derecho sobre la película->Obtener información->Desde internet usando un script)

Entonces te saldrá el menú que aparece en la imagen que puse más arriba. Selecciona el script "FilmAffinity (ES)". Asegúrate que en la información del script que aparece en la parte de abajo de la ventana aparece el número de versión correcto. Las opciones del script están en el lado derecho.

Espero que lo consigas!



Con respecto a las imágenes/carátulas, se bajan las que están publicadas en la página FilmAffinity.es... a veces hay suerte y están en castellano, y a veces solo están disponibles en inglés.

[visent]

@visent La mejor forma de actualizar el script es la siguiente:
1) Vas a la carpeta donde tengas instalado el Ant Movie Catalog, y entras en la carpeta "Scripts" (Ej: "C:\Archivos de programa (x86)\Ant Movie Catalog\Scripts")
2) Busca el fichero "FilmAffinity (ES).ifs" y ábrelo con el Bloc de notas (o cualquier otro editor de texto)
3) Borra todo el contenido del fichero y pega el código que encontrarás en la primera entrada de este post.

Cuando arranques la aplicación, añade una nueva película (o selecciona una que ya tengas añadida) y pulsa F6 (o haz Click derecho sobre la película->Obtener información->Desde internet usando un script)

Entonces te saldrá el menú que aparece en la imagen que puse más arriba. Selecciona el script "FilmAffinity (ES)". Asegúrate que en la información del script que aparece en la parte de abajo de la ventana aparece el número de versión correcto. Las opciones del script están en el lado derecho.

Espero que lo consigas!



Con respecto a las imágenes/carátulas, se bajan las que están publicadas en la página FilmAffinity.es... a veces hay suerte y están en castellano, y a veces solo están disponibles en inglés.

Ahora perfecto!!

Lo de las carátulas, no me había fijado que eran las de la web. Perfecto también.

Y ya puestos... en la imagen que adjunto



Cuando yo doy de alta una nueva peli, me aparece marcada, ¿se puede hacer que aparezca desmarcada?

[Keichi]

Un millón de gracias por la actualización!

[fotja]

Han vuelto a retocar la pagina de FilmAffinity, ahora no salen ni los premios ni los comentarios de criticas. Aver si dejan de retocar la pagina para que se quede el scrip correcto.

[aviloria]

He actualizado el script para adaptarse a los cambios en la página.
No dudéis en avisarme si algo dejó de funcionar o si hay más cambios.

-----

I have updated the script to complain with website changes.
Please, let me know about regresions and new updates.